1

我正在尝试创建一个扩展方法，该方法接受一个指向实体上的属性的表达式，以及一个将其与 using 进行比较的常量字符串，它String.Contains首先检查字符串是空还是空，并且仅在以下情况下应用过滤器字符串有一个值。这是我第一次涉足表达式树，所以我不太确定发生了什么，我现在有一个例外，我不知道如何治愈......

到目前为止，我在这里：

<System.Runtime.CompilerServices.Extension()>
    Public Function CheckAndFilter(Of T)(source As System.Linq.IQueryable(Of T), expressionField As System.Linq.Expressions.Expression(Of System.Func(Of T, String)), compareTo As String) As IQueryable(Of T)


        If String.IsNullOrEmpty(compareTo) Then
            Return source
        Else
            Dim memberExp As Expressions.MemberExpression = DirectCast(expressionField.Body, Expressions.MemberExpression)

            Dim param = Expressions.Expression.Parameter(GetType(T))
            Dim method As Reflection.MethodInfo = GetType(String).GetMethod("Contains")

            Dim compareToExpression = Expressions.Expression.Constant(compareTo)
            Dim finalExpr = Expressions.Expression.Call(memberExp, method, compareToExpression)

            Dim lambda = Expressions.Expression.Lambda(Of Func(Of T, Boolean))(finalExpr, param)
            Return source.Where(lambda)
        End If
    End Function

我这样称呼它，DbContext因为我有一个Customer带有FirstName字符串属性的实体：

Dim results = repository.Customers.CheckAndFilter(Function(c) c.FirstName, searchText)

例外是：

{"The parameter 'c' was not bound in the specified LINQ to Entities query expression."}

有什么想法吗？

4

1 回答 1

2

啊哈！

这是因为我声明了一个新参数，而不是重新使用通过表达式传入的参数...

<System.Runtime.CompilerServices.Extension()>
Public Function CheckAndFilter(Of T)(source As System.Linq.IQueryable(Of T), expressionField As System.Linq.Expressions.Expression(Of System.Func(Of T, String)), compareTo As String) As IQueryable(Of T)


    If String.IsNullOrEmpty(compareTo) Then
        Return source
    Else
        Dim memberExp As Expressions.MemberExpression = DirectCast(expressionField.Body, Expressions.MemberExpression)

        Dim method As Reflection.MethodInfo = GetType(String).GetMethod("Contains")

        Dim compareToExpression = Expressions.Expression.Constant(compareTo)
        Dim finalExpr = Expressions.Expression.Call(memberExp, method, compareToExpression)

        Dim lambda = Expressions.Expression.Lambda(Of Func(Of T, Boolean))(finalExpr, expressionField.Parameters)
        Return source.Where(lambda)
    End If
End Function
于 2012-03-02T10:38:55.347 回答