19

我们如何从命令行评估 Mathematica 笔记本（即在命令行模式下运行内核时）？

假设我们在远程机器上工作。我知道可以将笔记本转换为 m 文件并对其进行评估，但我很好奇是否可以直接使用笔记本进行此操作。

这是我到目前为止所拥有的：

首先，我们需要在远程 Linux 机器上启动一个无头 X 服务器，这样前端就可以在那里运行（并打开笔记本）。如果您在本地计算机上工作，请跳过此步骤。

Xvfb :1 &
export DISPLAY=:1

在此之后，我启动了一个 Mathematica 内核 ( math) 并执行了以下操作。

必须使用UsingFrontEnd，因为打开笔记本需要前端。test.nb 有一个包含a=1.

In[1]:= nb=UsingFrontEnd@NotebookOpen["test.nb"]

Out[1]= -NotebookObject-

在尝试评估笔记本后，显然我得到了一个对话框，我需要使用Return[]返回。我不确定为什么输入行再次从 1 开始计数（前端启动了一个新内核？）请注意，它a没有获得值。

In[2]:= UsingFrontEnd@NotebookEvaluate[nb]

 In[1]:= a

 Out[1]= a

 In[2]:= Return[]

Out[2]= a

从对话框返回后，a仍然没有值。

In[3]:= a

Out[3]= a
4

2 回答 2

11

这是您问题的部分答案。以下代码打开一个笔记本，为其分配一个“测试”内核，评估该内核中的笔记本，等待评估完成并保存评估的笔记本。虽然它不会导致a在本地命令行内核中定义。

这等待内核评估在笔记本中完成：

NotebookPauseForEvaluation[nb_] := Module[{},
 While[ NotebookEvaluatingQ[nb], Pause[.25] ] ]

这将检查笔记本中的任何单元格是否仍在评估中：

NotebookEvaluatingQ[nb_]:=Module[{},
 SelectionMove[nb,All,Notebook];
 Or@@Map["Evaluating"/.#&,Developer`CellInformation[nb]]
]

这只是一条诊断消息，当您尝试重新定义像“测试”这样的内核时：

AddTestEvaluator::exists = "Evaluator `1` is already defined, but has a definition that is `2` and not the expected `3`.";

这是向前端添加评估器的代码，例如“测试”：

AddTestEvaluator[evaluator_String] := Module[
 {evaluatornames, testevaluator},
 evaluatornames = EvaluatorNames /. Options[$FrontEnd, EvaluatorNames];
 testevaluator = evaluator -> {"AutoStartOnLaunch" -> False};
 Which[
  MemberQ[evaluatornames, evaluator -> {"AutoStartOnLaunch" -> False}],
  Null,
  MemberQ[evaluatornames, evaluator -> _],
  Message[AddTestEvaluator::exists,
  evaluator,
  evaluator /. (EvaluatorNames /. Options[$FrontEnd, EvaluatorNames]),
  {"AutoStartOnLaunch" -> False}
 ],
 True,
 AppendTo[evaluatornames, testevaluator];
 SetOptions[$FrontEnd, EvaluatorNames -> evaluatornames]
 ]
]

最后，这是在“测试”内核下评估笔记本并保存评估内核的代码：

 UsingFrontEnd[     
  AddTestEvaluator["Test"];
  nb = NotebookOpen["test.nb"];
  SetOptions[nb,Evaluator->"Test"];
  SelectionMove[nb,All,Notebook];
  SelectionEvaluate[nb];
  NotebookPauseForEvaluation[nb];
  NotebookSave[nb]
 ]

我仍在为您的全部问题寻找解决方案（已a在本地命令行内核中定义）。

于 2011-12-28T17:17:48.810 回答
10

这是在 Windows 上，使用 Arnouds 做的很好，只是添加了普通的旧 MathLink（顺便说一句相当慢......）：

link = LinkCreate["8000", LinkProtocol -> "TCPIP"];
UsingFrontEnd[
NotebookPauseForEvaluation[nb_] := Module[{},
 While[ NotebookEvaluatingQ[nb], Pause[.25] ] ];
NotebookEvaluatingQ[nb_]:=Module[{},
 SelectionMove[nb,All,Notebook];
 Or@@Map["Evaluating"/.#&,Developer`CellInformation[nb]]
];
nb = NotebookOpen["G:\\mma\\test.nb"];
SelectionMove[nb, Before, Notebook];
NotebookWrite[nb, Cell["Link = LinkConnect[\"8000\", LinkProtocol -> \"TCPIP\"]", "Input"]];
SelectionMove[nb, After, Notebook];
NotebookWrite[nb, Cell["LinkWrite[Link, a]", "Input"]];
SelectionMove[nb, All, Notebook];
SelectionEvaluate[nb];
a = LinkRead[link];
Print["a = ",a];
]
于 2011-12-28T18:40:31.840 回答