6

我想一次将所有附件保存到电子邮件中。因此，我将 gnus-summary-save-parts-default-mime 设置为“.* /.*”。但是，当使用“X m”时，我不仅会获得所有附件，还会获得一个名为“nnimap+my.name@googlemail.com/INBOX.2393.1”的文件（指的是我正在阅读电子邮件的帐户），其中包含我收到的电子邮件的签名。如何将这种“类型”的文件排除在“X m”上？换句话说：如何为 gnus-summary-save-parts-default-mime 指定正确的正则表达式以防止该文件也被保存？

4

1 回答 1

2

这defadvice将通过排除任何没有文件名的部分来做你想做的事情（在这种情况下，文章本身也是如此）：

(defadvice gnus-summary-save-parts-1 (around gnus-summary-save-parts-exclude-self activate)
  (let ((handle (ad-get-arg 2)))
    (unless (and (not (stringp (car handle)))
                 (not (mm-handle-filename handle)))
      ad-do-it)))

我正在使用 Gnus v5.13；如果您也使用相同或相似的版本，请告诉我此修改后的版本是否gnus-summary-save-parts-1适合您；您将要设置gnus-summary-save-parts-exclude-article为t. 如果它适合你，我会为它提交一个补丁到 Gnus 项目。

请注意，要么使用上面的代码，defadvice 要么使用下面的代码，但不要同时使用两者。defadvice 是一个简单的快速修复程序，您可以暂时使用它。下面的代码我将作为补丁提交给 Gnus 项目，我只在此处包含它以供您测试，如果您也使用 Gnus v5.13，它是否可以在您的系统上运行。如果他们接受此补丁并将其作为未来版本的一部分，那么您将不需要defadvice上述内容；相反，您将能够自定义gnus-summary-save-parts-exclude-article变量。

(require 'gnus)
(require 'gnus-sum)

(defcustom gnus-summary-save-parts-exclude-article nil
  "If non-nil don't save article along with attachments."
  :group 'gnus-article-mime
  :type 'boolean)

(defun gnus-summary-save-parts-1 (type dir handle reverse)
  (if (stringp (car handle))
      (mapcar (lambda (h) (gnus-summary-save-parts-1 type dir h reverse))
          (cdr handle))
    (when (if reverse
          (not (string-match type (mm-handle-media-type handle)))
        (string-match type (mm-handle-media-type handle)))
      (let* ((name (or
                    (mm-handle-filename handle)
                    (unless gnus-summary-save-parts-exclude-article
                      (format "%s.%d.%d" gnus-newsgroup-name
                              (cdr gnus-article-current)
                              gnus-summary-save-parts-counter))))
             (file (when name
                     (expand-file-name
                      (gnus-map-function
                       mm-file-name-rewrite-functions
                       (file-name-nondirectory
                        name))
                      dir))))
        (when file
          (incf gnus-summary-save-parts-counter)
          (unless (file-exists-p file)
            (mm-save-part-to-file handle file)))))))
于 2011-12-07T14:13:50.170 回答