5

在较高的层次上,我理解使用转换器不会创建任何中间数据结构,而通过长链操作->>确实可以,因此转换器方法的性能更高。这在我下面的一个例子中被证明是正确的。但是,当我添加clojure.core.async/chan到组合中时,我并没有得到我期望的相同的性能改进。显然有些东西我不明白,我会很感激解释。

(ns dev
  (:require [clojure.core.async :as async]

            [criterium.core :as crit]))

;; Setup some toy data.
(def n 1e6)
(def data (repeat n "1"))


;; Reusable thread-last operation (the "slower" one).
(defn tx [x]
  (->> x
       (map #(Integer. %))
       (map inc) (map inc) (map inc) (map inc) (map inc) (map inc)
       (map inc) (map inc) (map inc) (map inc) (map inc)))

;; Reusable transducer (the "faster" one).
(def xf (comp
          (map #(Integer. %))
          (map inc) (map inc) (map inc) (map inc) (map inc) (map inc)
          (map inc) (map inc) (map inc) (map inc) (map inc)))

;; For these first two I expect the second to be faster and it is.
(defn nested []
  (last (tx data)))

(defn into-xf []
  (last (into [] xf data)))

;; For the next two I again expect the second to be faster but it is NOT.
(defn chan-then-nested []
  (let [c (async/chan n)]
    (async/onto-chan! c data)
    (->> c
         (async/into [])
         async/<!!
         tx
         last)))

(defn chan-xf []
  (let [c (async/chan n xf)]
    (async/onto-chan! c data)
    (->> c
         (async/into [])
         async/<!!
         last)))

(comment

  (crit/quick-bench (nested)) ; 1787.672 ms
  (crit/quick-bench (into-xf)) ; 822.8626 ms
  (crit/quick-bench (chan-then-nested)) ; 1535.628 ms
  (crit/quick-bench (chan-xf)) ; 2072.626 ms

  ;; Expected ranking fastest to slowest
  ;; into-xf
  ;; nested
  ;; chan-xf
  ;; chan-then-nested

  ;; Actual ranking fastest to slowest
  ;; into-xf
  ;; chan-then-nested
  ;; nested
  ;; chan-xf

  )

最后有两个我不明白的结果。首先,为什么使用带有通道的传感器比读取通道中的所有内容然后执行嵌套映射要慢?似乎使用带有通道的转换器的“开销”或其他任何东西要慢得多,以至于它压倒了不创建中间数据结构的收益。其次,这个实在是出乎意料,为什么把数据放到一个通道上,然后把它取下来,然后使用嵌套映射技术比不做通道跳舞而只使用嵌套映射技术要快?(说得更短,为什么chan-then-nestednested?)这一切或部分只是基准测试或随机性的产物吗?(我跑了quick-bench每一个都有几次相同的结果。)我想知道它是否与into调用transduce有关,而在通道版本中根本没有以相同的方式实现。转换器为跨向量或通道应用变换提供了相同的接口,但应用变换的方式不同;这种差异使一切变得不同。

4

1 回答 1

3

关于您的方法的一些评论:

  • 有一个缓冲区大小为 100 万的通道是非常不寻常的。我不希望从这种用法中得出的基准对现实世界的程序有很大的适用性。只需使用 1 的缓冲区大小。这足以让这个应用程序成功,并且更接近于真实世界的使用情况。
  • 没必要挑这么大的n。如果您的函数运行得更快,则 criterium 可以获取更多样本,从而更准确地估计其平均时间。n=100 就足够了。

进行这些更改后,这是我看到的基准数据:

Evaluation count : 14688 in 6 samples of 2448 calls.
             Execution time mean : 39.978735 µs
    Execution time std-deviation : 1.238587 µs
   Execution time lower quantile : 38.870558 µs ( 2.5%)
   Execution time upper quantile : 41.779784 µs (97.5%)
                   Overhead used : 10.162171 ns
Evaluation count : 20094 in 6 samples of 3349 calls.
             Execution time mean : 30.557295 µs
    Execution time std-deviation : 562.641738 ns
   Execution time lower quantile : 29.936152 µs ( 2.5%)
   Execution time upper quantile : 31.330094 µs (97.5%)
                   Overhead used : 10.162171 ns
Evaluation count : 762 in 6 samples of 127 calls.
             Execution time mean : 740.642963 µs
    Execution time std-deviation : 176.879454 µs
   Execution time lower quantile : 515.588780 µs ( 2.5%)
   Execution time upper quantile : 949.109898 µs (97.5%)
                   Overhead used : 10.162171 ns

Found 2 outliers in 6 samples (33.3333 %)
    low-severe   1 (16.6667 %)
    low-mild     1 (16.6667 %)
 Variance from outliers : 64.6374 % Variance is severely inflated by outliers
Evaluation count : 816 in 6 samples of 136 calls.
             Execution time mean : 748.782942 µs
    Execution time std-deviation : 7.157018 µs
   Execution time lower quantile : 740.139618 µs ( 2.5%)
   Execution time upper quantile : 756.102312 µs (97.5%)
                   Overhead used : 10.162171 ns

关键要点是:

  1. 异步开销支配实际处理时间。两个通道版本都比任何一个非通道版本都慢得多,所以我们再也不用担心“为什么把整个东西放到一个通道上然后再取下来会更快”。
  2. chan-then-nested和之间的差异chan-xf比您的版本小得多。chan-xf仍然有点慢,但很容易在一个标准偏差内:这并不是一个显着的结果。
于 2021-01-17T06:03:31.783 回答