0

我有一个包含许多 json 文件的文件夹。我需要处理这些文件并将它们存储在 mysql 数据库中。为了做到这一点，我正在尝试创建一个 grails cmd 脚本（因为该项目使用的是 Grails 2.5.6）。所以，我做的第一件事是：grails create-script upload-json-files，然后 grails 创建了我的脚本，如下所示：

includeTargets << grailsScript("_GrailsInit")

target(uploadJson: "The description of the script goes here!") {
    doStuff()
}

target (doStuff: "The implementation task") {
}

setDefaultTarget(uploadJson)

我希望我的脚本在 args 中获取所有 JSON 文件的目录路径，获取每个文件并对其进行处理，将其存储在数据库中。在我的 grails 项目中，我有一些域类，我正在使用 GORM 在我的数据库中检索和保存新对象。在我的 grails 脚本中访问我的域类并使用 GORM 方法将它们保存在我的数据库中是否可行？我已经尝试导入我的域类，但它不起作用。而且我在 grails 2.5 文档中找不到任何内容。

4

1 回答 1

1

请参阅https://github.com/jeffbrown/federicobaioccoscript上的项目。

脚本中的注释描述了正在发生的事情。

https://github.com/jeffbrown/federicobaioccoscript/blob/977df5aedff04cec47d8c25900b4048cf1e12fe8/scripts/PopulateDb.groovy

includeTargets << grailsScript('_GrailsBootstrap')

target(populateDb: "Target demonstrates one approach to using domain classes in a script") {
    depends classpath, bootstrap

    // load the Person class
    def personClass = classLoader.loadClass('federicobaioccoscript.Person')

    // the question is about using domain classes in a script, not
    // about parsing JSON files so here the peopleData is hardcoded instead
    // of complicating the example with file i/o.
    def peopleData = []
    peopleData << [firstName: 'Geddy', lastName: 'Lee']
    peopleData << [firstName: 'Neil', lastName: 'Peart']
    peopleData << [firstName: 'Alex', lastName: 'Lifeson']

    // create and persist instances of the Person class
    personClass.withNewSession {
        peopleData.each { personData ->
            // create an instance of the Person class
            def person = personClass.newInstance personData

            // save the instance to the database
            person.save()
        }
    }

    // this is only here to demonstrate that the data
    // really is in the database...
    personClass.withNewSession {
        List people = personClass.list()

        println people
    }
}

setDefaultTarget(populateDb)

如果您克隆该存储库并运行，./grailsw populate-db您将看到该脚本有效。

我希望这会有所帮助。

于 2020-02-08T03:56:55.220 回答