3

我不仅想返回 JSON，还想返回 HTTP 响应代码。

我通过 URLRouter 注册 REST 接口：

router.registerRestInterface(new ClientServerAPI);

我的 REST 实现示例：

module clienserverapi.clientserver;

import api.clientserver;
import models.replies.client_versions;

/**
    Implementation of Client-Server API.
*/
class ClientServerAPI : IClientServerAPI {
@safe:
    ClientVersions getSupportedClientVersions() {
        bool[string] unstableFeatures;
        return ClientVersions(supportedVersions.dup, unstableFeatures);
    }
}
4

2 回答 2

4

在 REST 接口生成器中，响应代码是自动处理的，由于您无法将 HTTPServerResponse/HTTPServerRequest 参数传递到 REST 方法中，因此您无法控制返回的状态。

但是，有一些内置状态可以处理：

  • 200/204 根据内容返回
  • 400 对不匹配参数的错误请求
  • 404 Not found for unmatched routes
  • 大多数异常返回 500 内部服务器错误
  • （在调试模式之外）发送未授权/错误请求/禁止

另请参阅：REST 接口文档

并且您可以使用HTTPStatusException控制任何状态代码，但是它被视为错误并会导致预定义的错误 json 将 statusMessage 作为异常消息集并返回您传递给它的 HTTP 状态代码。（这可能是你想要的错误处理）

您还可以通过将errorHandler设置为 RestInterfaceSettings 中的RestErrorHandler委托来更改错误的外观。

或者，根据您想要做什么，您可以使用一个 WebInterface，它很像一个休息接口，但没有 REST 接口做的一些便利功能，而是可以完全访问请求/响应参数并且基本上可以做任何类似于普通 http 路由的东西，并具有您可以使用的其他一些便利功能。

从理论上讲，如果您想用您的数据返回自定义成功代码，您可以使用有效的 HTTP 状态代码滥用 errorHandler + HTTPStatusException，但我不鼓励这样做，而是使用 Web 界面，如果这是您所追求的。

但是，如果您只想使用自定义但一致的错误页面使用自定义错误代码，那么我肯定会使用带有 errorHandler 的 REST 接口。

你的可能现在看起来像这样：

import vibe.vibe;
import std.uni;

@safe:

void main() {
    auto server = new HTTPServerSettings;
    server.port = 3000;
    server.bindAddresses = ["::1", "127.0.0.1"];
    auto router = new URLRouter;

    RestInterfaceSettings settings = new RestInterfaceSettings();
    // this is how the error page will look on any thrown exception (like HTTPStatusException)
    settings.errorHandler = (HTTPServerRequest req, HTTPServerResponse res,
            RestErrorInformation error) @safe {
        res.writeJsonBody([
            // design this however you like
            "ok": Json(false),
            "error": serializeToJson([
                "status": Json(cast(int)error.statusCode),
                "message": Json(error.exception.msg),
                "parent": Json("/api/something")
            ])
        ]);
    };
    router.registerRestInterface(new Impl, settings);

    listenHTTP(server, router);
    runApplication();
}

interface RestAPI {
    string getGreeting(string name);
}

class Impl : RestAPI {
    string getGreeting(string name)
    {
        // throw an HTTP Bad Request error when name is empty
        if (name.length == 0)
            throw new HTTPStatusException(HTTPStatus.badRequest, "Name parameter cannot be empty!");
        // throw an HTTP Conflict error code when name is Bob
        if (sicmp(name, "bob") == 0)
            throw new HTTPStatusException(HTTPStatus.conflict, "Server cannot greet Bob!");
        return "Hello, " ~ name ~ "!";
    }
}

然后您的服务器将响应如下内容：

{
    "ok": false,
    "error": {
        "message": "Server cannot greet Bob!",
        "status": 409,
        "parent": "/api/something"
    }
}
于 2019-07-13T15:41:09.553 回答
0

你可以试试 Hunt 框架，Rest api 的示例代码：

module app.controller.myapi;

import hunt.framework;

import app.message.UserMessage;

class MyapiController : Controller
{
    mixin MakeController;

    @Action
    JsonResponse test()
    {
        UserMessage user;
        user.id = 1;
        user.name = "MyName";
        user.email = "test@domain.com";

        return new JsonResponse(user);
    }
}

您的响应结构：

module app.message.ResultMessage;

struct UserMessage
{
    int id;
    string name;
    string email;
}

响应结果为：

[ "id": 1, "name": "MyName", "email": "test@domain.com" ]
于 2019-07-26T11:02:06.597 回答