0

对于以下输入，我在条件增量方面遇到问题。

条件：在我预期的输入中 5 将被重复。如果元素重复并且仅当它的值等于 5 时，我想向元素添加版本控制

输入

<?xml version="1.0"?><?xml-stylesheet type="text/xsl"?> <data> <rec>
    <Pt>1</Pt>
  </rec>
  <rec>
    <Pt>3</Pt>
  </rec>
  <rec>
    <Pt>5</Pt>
  </rec>
  <rec>
    <Pt>5</Pt>
  </rec>
  <rec>
    <Pt>5</Pt>
  </rec>
  <rec>
    <Pt>6</Pt>
  </rec>
</data>

预期输出：

<?xml version="1.0" encoding="UTF-8"?>
<Record>
    <PT>1</PT>
    <DerivedPT>1</DerivedPT>
</Record>
<Record>
    <PT>3</PT>
    <DerivedPT>3</DerivedPT>
</Record>
<Record>
    <PT>5</PT>
    <DerivedPT>5.1</DerivedPT>
</Record>
<Record>
    <PT>5</PT>
    <DerivedPT>5.2</DerivedPT>
</Record>
<Record>
    <PT>5</PT>
    <DerivedPT>5.3</DerivedPT>
</Record>
<Record>
    <PT>6</PT>
    <DerivedPT>6</DerivedPT>
</Record>

我试过这个 XSLT：

<?xml version="1.0"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="1.0">
    <xsl:template match="/">
        <xsl:for-each select="data/rec">
            <Record>
                <PT>
                    <xsl:value-of select="Pt" />
                </PT>
                <DerivedPT>
                    <xsl:variable name="pt" select="Pt" />
                    <xsl:choose>
                        <xsl:when test="contains($pt,'5')">
                            <xsl:value-of
                                select="concat($pt,'.',count(preceding-sibling::rec/Pt[1])+1)" />
                        </xsl:when>
                        <xsl:otherwise>
                            <xsl:value-of select="$pt" />
                        </xsl:otherwise>
                    </xsl:choose>
                </DerivedPT>
            </Record>
        </xsl:for-each>
    </xsl:template>
</xsl:stylesheet>

但是，我得到的输出是：

<?xml version="1.0" encoding="UTF-8"?>
<Record>
    <PT>1</PT>
    <DerivedPT>1</DerivedPT>
</Record>
<Record>
    <PT>3</PT>
    <DerivedPT>3</DerivedPT>
</Record>
<Record>
    <PT>5</PT>
    <DerivedPT>5.3</DerivedPT>
</Record>
<Record>
    <PT>5</PT>
    <DerivedPT>5.4</DerivedPT>
</Record>
<Record>
    <PT>5</PT>
    <DerivedPT>5.5</DerivedPT>
</Record>
<Record>
    <PT>6</PT>
    <DerivedPT>6</DerivedPT>
</Record>

这是因为它正在挑选所有标签。我必须进行哪些更改，所以它只需要 5 的 PT。

                        <xsl:value-of
                            select="concat($pt,'.',count(preceding-sibling::rec/Pt[1])+1)" />
4

3 回答 3

1

为了更好的可读性，我在变量中设置了颠覆号，但以下内容非常适合您的要求。将您的内容替换为<xsl:choose>以下内容：

<xsl:when test="contains($pt,'5')">
  <xsl:variable name="thisSubversion" select="count(preceding-sibling::rec[Pt='5']) + 1" />
  <xsl:value-of select="concat($pt,'.', $thisSubversion)" />
</xsl:when>

这使您可以仅查看rec/Pt值为“5”的节点的值。我希望这有帮助！

https://xsltfiddle.liberty-development.net/3NJ38Zz

于 2019-05-21T10:54:17.817 回答
1

虽然可能只有 5 次重复，但这可能是一个使用称为Muenchian Grouping的技术的机会，因为它是一种很好的学习技术（假设您仅限于 XSLT 1.0）

在这种情况下，您可以重写您的 XSLT，如下所示...

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  <xsl:output method="xml" indent="yes" />

  <xsl:key name="recs" match="rec" use="Pt" />

  <xsl:template match="data">
    <xsl:copy>
      <xsl:for-each select="rec[generate-id() = generate-id(key('recs', Pt)[1])]">
         <xsl:apply-templates select="key('recs', Pt)" />
      </xsl:for-each>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="rec">
    <Record>
      <xsl:copy-of select="Pt" />
      <DerivedPT>
        <xsl:value-of select="Pt" />
        <xsl:if test="Pt = '5'">
          <xsl:value-of select="concat('.',position())" />
        </xsl:if>
      </DerivedPT>
    </Record>
  </xsl:template>
</xsl:stylesheet>

这里的好处是，如果您确实希望所有记录都具有逻辑，而不仅仅是“5”，那么您只需删除xsl:if条件。

而且，如果你有一个大的结构，这应该比不断地计算前面的兄弟姐妹的数量更有效。

于 2019-05-21T11:25:40.780 回答
1

我也希望避免重复倒数，而是做这样的事情：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:template match="rec">
    <Record>
        <PT>
            <xsl:value-of select="Pt" />
        </PT>
        <DerivedPT>
            <xsl:choose>
                <xsl:when test="Pt=5">
                    <xsl:text>5.</xsl:text>
                    <xsl:number count="rec[Pt=5]"/>
                </xsl:when>
                <xsl:otherwise>
                    <xsl:value-of select="Pt" />
                </xsl:otherwise>
            </xsl:choose>
        </DerivedPT>
    </Record>
</xsl:template>

</xsl:stylesheet>
于 2019-05-21T14:24:30.033 回答