plot - pinescript - 当 EMA 在高于/低于 200 移动平均线时穿过 SMA 时绘制交叉

Question

我对 pinescript 非常陌生，我被困在这一点上......我只想在 10 EMA 超过 21 EMA 而 21 高于 50 EMA 并且 50 EMA 高于 200 EMA 时绘制一个交叉。这是表示长信号。同时，当 10 EMA 超过 21 EMA，而 21 低于 50 EMA 并且 50 EMA 低于 200 EMA。这是指示短信号。

我有这么多代码，但我不知道如何进一步进行：

//@version=3
study(title="MA Cross ATTEMPT", overlay=true)

s10ema = ema(close, 10)
s21ema = ema(close, 21)
s50ema = ema(close, 50)
s200ema = ema(close, 200)

plot(s10ema, color = red, linewidth = 1, transp=0)
plot(s21ema, color = aqua, linewidth = 1, transp=0)
plot(s50ema, color = aqua, linewidth = 2, transp=0)
plot(s200ema, color = red, linewidth = 2, transp=0)

mycond = s200ema < s50ema and s50ema < s21ema and s21ema < s10ema
EMACross = cross(s10ema, s21ema) ? s10ema : na, style = cross, linewidth = 4, color = yellow, transp=0

plot(?????)

任何帮助将不胜感激

Answer 1

做到这一点的方法是使用该plotshape()功能。还有不同的plot功能，但我更喜欢plotshape()为此目的使用。一定要检查其他plot功能。Tradingview 有一个很好的 pine-script 文档。

此外，如果两个系列相互交叉，则cross()返回。1可以是下面的，也可以是上面的，没关系。但是，您想在发生情况时触发您的条件crossover。crossover()为此目的调用了一个函数（另请参见crossunder()相反的内容）。

//@version=3
study(title="MA Cross ATTEMPT", overlay=true)

s10ema = ema(close, 10)
s21ema = ema(close, 21)
s50ema = ema(close, 50)
s200ema = ema(close, 200)

plot(s10ema, title="Ema 10", color = red, linewidth = 1, transp=0)
plot(s21ema, title="Ema 21", color = aqua, linewidth = 1, transp=0)
plot(s50ema, title="Ema 50", color = orange, linewidth = 2, transp=0)
plot(s200ema, title="Ema 200", color = blue, linewidth = 2, transp=0)

longCond = crossover(s10ema, s21ema) and (s21ema > s50ema) and (s50ema > s200ema)
shortCond = crossunder(s10ema, s21ema) and (s21ema < s50ema) and (s50ema < s200ema)

plotshape(series=longCond, title="Long", style=shape.triangleup, location=location.belowbar, color=green, text="LONG", size=size.small)
plotshape(series=shortCond, title="Short", style=shape.triangledown, location=location.abovebar, color=red, text="SHORT", size=size.small)