96

我需要为不同的用户启动一堆 EC2 盒子。每个用户都应该被沙盒化，因此每个 EC2 框都需要自己的 SSH 密钥。

在 Terraform 中完成此任务的最佳方法是什么？

我发现的几乎所有说明都希望我手动创建 SSH 密钥并将其粘贴到 terraform 脚本中。

（坏）例子：

由于我需要以编程方式为许多用户生成唯一密钥，因此这是不切实际的。

这似乎不是一个困难的用例，但我在任何地方都找不到文档。

在紧要关头，我可以生成 Terraform 脚本并使用 Bash 即时注入 SSH 密钥。但这似乎正是 Terraform 一开始就应该做的事情。

4

5 回答 5

161

tls_private_keyTerraform 可以使用资源生成 SSL/SSH 私钥。

因此，如果您想即时生成 SSH 密钥，您可以执行以下操作：

variable "key_name" {}

resource "tls_private_key" "example" {
  algorithm = "RSA"
  rsa_bits  = 4096
}

resource "aws_key_pair" "generated_key" {
  key_name   = var.key_name
  public_key = tls_private_key.example.public_key_openssh
}

data "aws_ami" "ubuntu" {
  most_recent = true

  filter {
    name   = "name"
    values = ["ubuntu/images/hvm-ssd/ubuntu-focal-20.04-amd64-server-*"]
  }

  filter {
    name   = "virtualization-type"
    values = ["hvm"]
  }

  owners = ["099720109477"] # Canonical
}

resource "aws_instance" "web" {
  ami           = data.aws_ami.ubuntu.id
  instance_type = "t2.micro"
  key_name      = aws_key_pair.generated_key.key_name

  tags {
    Name = "HelloWorld"
  }
}

这将创建一个处于 Terraform 状态的 SSH 密钥对（它不会在文件中写入磁盘，而不是在不使用远程状态时对 Terraform 状态本身执行的操作），基于公钥创建一个 AWS 密钥对然后创建一个 Ubuntu 14.04 实例，ubuntu用户可以使用生成的私钥访问该实例。

然后，您必须从状态文件中提取私钥并将其提供给用户。应用 Terraform 时，您可以使用 anoutput直接将其吐出到标准输出。

安全警告

我应该在这里指出，传递私钥通常是一个坏主意，最好让开发人员创建他们自己的密钥对并为您提供您（或他们）可以用来生成 AWS 密钥对的公钥（可能使用上面示例中使用的aws_key_pair资源）然后可以在创建实例时指定。

一般来说，我只会使用类似上述方式为您正在控制的非常临时的开发环境生成 SSH 密钥，因此您不需要将私钥传递给任何人。如果确实需要将私钥传递给人们，则需要确保在安全通道中执行此操作，并确保 Terraform 状态（包含纯文本私钥）也得到适当保护。

于 2018-04-12T09:24:35.670 回答
18

2022 年 2 月更新：

下面的代码创建myKeytoAWS和myKey.pemtoyour computer以及 created myKeyandmyKey.pem具有相同的私钥。（我用过Terraform v0.15.4）

resource "tls_private_key" "pk" {
  algorithm = "RSA"
  rsa_bits  = 4096
}

resource "aws_key_pair" "kp" {
  key_name   = "myKey"       # Create "myKey" to AWS!!
  public_key = tls_private_key.pk.public_key_openssh

  provisioner "local-exec" { # Create "myKey.pem" to your computer!!
    command = "echo '${tls_private_key.pk.private_key_pem}' > ./myKey.pem"
  }
}

不要忘记myKey.pem只有在 ssh 到您的 ec2 实例之前运行下面的代码才能使其可读。

chmod 400 myKey.pem

否则会出现以下错误。

@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
@         WARNING: UNPROTECTED PRIVATE KEY FILE!          @
@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
Permissions 0664 for 'myKey.pem' are too open.
It is required that your private key files are NOT accessible by others.
This private key will be ignored.
Load key "myKey.pem": bad permissions
ubuntu@35.72.30.251: Permission denied (publickey).
于 2021-05-04T06:36:23.263 回答
10

对先前答案的扩展，不适合评论：

要将生成的密钥写入具有正确权限的私有文件：

resource "local_file" "pem_file" {
  filename = pathexpand("~/.ssh/${local.ssh_key_name}.pem")
  file_permission = "600"
  directory_permission = "700"
  sensitive_content = tls_private_key.ssh.private_key_pem
}

然而，像这样保存文件的一个缺点是路径最终会处于 terraform 状态。如果只是 CI/CD 和/或一个运行 terraform 的人申请，这没什么大不了的，但如果有更多“应用程序”，则只要与上次应用运行不同的人申请，tfstate 就会更新。这将产生一些“更新”噪音。没什么大不了的，但需要注意的事情。

避免这种情况的另一种方法是将 pem 文件保存在 AWS Secrets Manager 中，或在 S3 中加密，并提供一个命令来获取它并创建本地文件。

于 2021-06-02T04:02:47.320 回答
4

添加到凯的答案：

variable "generated_key_name" {
  type        = string
  default     = "terraform-key-pair"
  description = "Key-pair generated by Terraform"
}

resource "tls_private_key" "dev_key" {
  algorithm = "RSA"
  rsa_bits  = 4096
}

resource "aws_key_pair" "generated_key" {
  key_name   = var.generated_key_name
  public_key = tls_private_key.dev_key.public_key_openssh

  provisioner "local-exec" {    # Generate "terraform-key-pair.pem" in current directory
    command = <<-EOT
      echo '${tls_private_key.dev_key.private_key_pem}' > ./'${var.generated_key_name}'.pem
      chmod 400 ./'${var.generated_key_name}'.pem
    EOT
  }

}
于 2021-06-26T04:52:51.023 回答
1

您必须将其与@ydaetskcoR 答案一起添加

output "ssh_key" {
  description = "ssh key generated by terraform"
  value       = tls_private_key.asg_lc_key.private_key_pem
}
于 2021-06-25T11:05:54.260 回答