3

我正在穿过一组嵌套块，并希望在找到我正在寻找的值时停止步行。

由于超出此问题范围的原因，我不能使用 PARSE 解决这个特定问题，也不能使用 FOREACH 作为循环器：

walk: func [series [block!] criteria [block!]][
    use [value] compose/deep [
        while [not tail? series][
            value: pick series 1

            either block? value [
                walk value criteria
            ][
                (to paren! criteria)
            ]

            series: next series
        ]
    ]
]

如果我找到这个特定的值，我想打破。

walk [a [b c [d e] f] g] [if value = 'e [return value]]
; returns 'e

但是，我也想做不会爆发的操作：

walk [a [b c [d e] f] g] [
    collect [if find [c e] value [keep value]]
]
; returns [c e]

想尝试解决包括 Red 在内的任何 Rebol 口味的问题。任何关于效率的想法（因为我使用块而不是函数）等也会受到欢迎。

4

2 回答 2

2

我正在寻找的功能组合是 CATCH/THROW。再一次，使用给定的函数：

walk: func [series [block!] criteria [block!]][
    use [value] compose/deep [
        while [not tail? series][
            value: pick series 1

            either block? value [
                walk value criteria
            ][
                (to paren! criteria)
            ]

            series: next series
        ]
    ]
]

我可以简单地将其包装如下：

catch [walk [a [b c [d e] f] g] [if value = 'e [throw value]]]
; returns 'e

一些笔记

  • 如果没有匹配项，我希望函数返回 NONE

我只会让 WALK 返回 NONE （我正在使用 ALSO 只是为了不留下尴尬的尾随none）：

 walk: func [series [block!] criteria [block!]][
      also none use [value] compose/deep [
          while [not tail? series][
              value: pick series 1

              either block? value [
                  walk value criteria
              ][
                  (to paren! criteria)
              ]

              series: next series
          ]
      ]
  ]
  • 没有 USE 功能

这引入了一个复杂性，因为我只想将块绑定到单词 VALUE。如果我要重写函数如下：

walk: func [series [block!] criteria [block!] /local value][
    do bind compose/deep [
        while [not tail? series][
            value: pick series 1

            either block? value [
                walk value criteria
            ][
                (to paren! criteria)
            ]

            series: next series
        ]
    ] 'value
]

然后它还将同一个块绑定到单词 SERIES 和 CRITERIA ，这将覆盖调用上下文中任何此类单词的绑定，例如：

walk [some values][series: none probe value] ; results in error
于 2017-07-10T17:51:48.357 回答
2

此版本避免绑定除 VALUE 之外的任何内容，并且适用于 Red 0.6.3 和 Rebol2：

walk: func [series [block!] criteria [block!]][
    also none do bind compose/deep [
        while [not tail? series] [
            value: pick series 1
            either block? value [
                walk value criteria
            ] [
                (to paren! criteria)
            ]
            series: next series
        ]
    ]
    context [value: none]
]

（欢迎评论此实现与 USE 的不同之处。）

是的，这不适用于 Rebol3 Alpha。但是使用 USE 的也不是。我认为这是一个THROW问题。

于 2017-08-25T15:08:52.467 回答