1

我正在使用 Neo4j 尝试查找未连接到特定节点“a”的任何节点。到目前为止，我的查询是：

MATCH p = shortestPath((a:Node {id:"123"})-[*]-(b:Node))
WHERE p IS NULL
RETURN b.id as b

所以它试图找到a和b之间的最短路径。如果它没有找到路径，则返回该节点的 id。但是，这会导致我的查询运行几分钟，然后在内存不足时崩溃。我想知道这种方法是否可行，是否有更有效的方法？任何帮助将不胜感激！

编辑：

MATCH (a:Node {id:"123"})-[*]-(b:Node),
(c:Node)
WITH collect(b) as col, a, b, c
WHERE a <> b AND NOT c IN col
RETURN c.id

所以 col (collect(b)) 包含连接到 a 的每个节点，因此如果 c 不在 col 中，那么 c 不连接到 a？

4

1 回答 1

1

一方面，你给这个 MATCH 一个不可能实现的谓词，所以它永远不会找到最短路径。

WHERE 子句与 MATCH、OPTIONAL MATCH 和 WITH 子句相关联，因此您的查询要求找到该路径不存在的最短路径。那将永远不会返回任何东西。

此外，shortestPath 将从您不想连接的节点开始，因此无法找到未连接到它的节点。

解决此问题的最简单方法可能是 MATCH 到所有连接到相关节点的节点，然后 MATCH 到所有 :Nodes 检查那些不在连接集中的节点。这意味着您不必从数据库中的每个节点执行 shortestPath，只需在集合中进行成员资格检查。

为此，您需要APOC 程序，因为它具有匹配子图中节点的最快方法。

MATCH (a:Node {id:"123"})
CALL apoc.path.subgraphNodes(a, {}) YIELD node
WITH collect(node) as subgraph
MATCH (b:Node)
WHERE NOT b in subgraph
RETURN b.id as b

编辑

您编辑的查询可能会爆炸，这将生成一个巨大的结果集（该查询将构建一个结果集，该结果集包含从您的起始节点可通过每个 :Node 的笛卡尔积中的唯一路径到达的每个节点）。

相反，请逐步收集不同的节点（因为否则您将获得可以通过不同路径到达的多个相同节点），然后只有在您收集完之后才开始匹配“ t 在列表中。

MATCH (:Node {id:"123"})-[*0..]-(b:Node)
WITH collect(DISTINCT b) as col
MATCH (a:Node)
WHERE NOT a IN col
RETURN a.id
于 2017-04-22T22:28:18.780 回答