list - 无限序列方案制作无限序列

Question

我有一个计划中的项目，我需要在其中实现无限的数字序列。我不能使用任何方案内置的复杂函数，而且我只是不知道如何使我的序列无限，而不会使程序在无限循环中崩溃。我不必真正输出它，但我需要能够使用它。

(seq n)   ;;output: n,n+1,n+2,n+3.... to infinity (seq 5) ->5,6,7,8,9...

现在我做了一个序列直到 n+7，但我需要这个到无穷大：

(define (seq n)
   (define (asc-order LIST counter)
     (cond ((= counter (+ n 7)) LIST)
           (else (asc-order (append LIST (cons (+ counter 1) '()))  
           (+ counter 1)))))
(asc-order '() (- n 1))
)

IO 示例（它有效，但我需要它无限序列）：

>(define s (seq 3)) 
>(car s)   
3

Answer 1

您可以将无限序列表示为一次生成一个元素的函数。然后，用户（消费者）可以调用该函数，每个需要序列的新元素。

一个例子：

(define (f x) (* x x))

(define seq
  (let ()
    (define n 0)        ; current index
    (lambda ()          ; the function that is to be called repeatedly
      (define a (f n))  ;   compute the new element
      (set! n (+ n 1))  ;   compute new index
      a)))              ;   return the new element

(seq)  ; compute element 0
(seq)  ; compute element 1
(seq)  ; ...
(seq)
(seq)
(seq)

这评估为：

0
1
4
9
16
25

为了编写(sequence->list s n)哪个计算n序列的第一个元素，请创建一个按总次数s调用的循环- 并将结果收集到一个列表中。sn

Answer 2

关键是通过围绕它包装一个过程来延迟对列表的评估。

这是我能想到的最简单的实现。
它只是在尾巴上“懒惰”。

(define (seq n)
  (cons n (lambda () (seq (+ n 1)))))

(define (seq-car s)
  (car s))

(define (seq-cdr s)
  ((cdr s)))

示例使用：

; Get the 'n' first elements of 's'.
(define (seq-take n s)
  (if (<= n 0)
      '()
      (cons (seq-car s) (seq-take (- n 1) (seq-cdr s)))))


> (define s (seq 10))
> s
'(10 . #<procedure>)
> (seq-take 5 s)
'(10 11 12 13 14)

Answer 3

这是使用延迟评估的另一种解决方案：

(use-modules (ice-9 receive))


(define (seq f)
  (let loop ((n 0))
    (lambda ()
      (values (f n) (loop (1+ n))))))


(define squares (seq (lambda (x) (* x x))))

(receive (square next) (squares)
  (pk square) ;; => 0
  (receive (square next) (next)
    (pk square) ;; => 1
    (receive (square next) (next)
      (pk square) ;; => 4
      (receive (square next) (next)
        (pk square))))) ;; => 9