2

我有一个传感器（实际上是 Quartzonix 压力传感器），它通过串行端口输出数据，大约每秒 3 次。我想设置一些代码，以便根据 x 数量的样本给我一个平均读数。

输出看起来像这样：

01+   1.502347091823e01
01+   1.501987234092e01
01+   1.50234524524e01
01+   1.502123412341e01
01+   1.502236234523e01
01+   1.50198345e01
01+   1.502346234523e01

.. 并且会一直持续下去，直到 com 端口关闭或传感器收到另一个命令。

这是我到目前为止的代码，代码可以向我展示传感器实际输出的内容：

Private Sub btnStart_Click(sender As Object, e As EventArgs) Handles btnStart.Click
    Dim a As String
    a = "$01MC" & Chr(13)
    MyComPort.WriteLine(a)

    Do
        Dim Incoming As String = MyComPort.ReadLine()
        Dim incomingtext As String = Incoming.Remove(0, 3)

        If Incoming Is Nothing Then
            Exit Do
        Else
            txtRawData.Text = Incoming
            boxPSIA.Text = Format(Val(incomingtext), "##0.000")

        End If
        Application.DoEvents()
    Loop

End Sub

“$01MC”是传感器开始输出数据所需的命令。当我单击开始按钮时，我发生了一些奇怪的超时事情，但那是另一个节目（可能需要 .readtimeout 调整，不确定）。

我有一个文本框 txtReadingsToAvg 用于输入要平均多少读数。 ，甚至进入另一个文本框）。

4

1 回答 1

1

不知道你的代码是如何工作的。你说你得到大约 3 Hz 的值？那么直线上升Do...Loop太快了。串口接收数据时会引发一个事件。好好利用它。

您可能需要稍微更改一下以满足您的需要

' WithEvents allows events to be handled with "Handles" keyword
Private WithEvents myComPort As SerialPort
Private dataQueue As Queue(Of Double)
Private numReadingsToAvg As Integer = 0

Private Sub btnStart_Click(sender As Object, e As EventArgs) Handles btnStart.Click
    ' make a new queue here to initialize or clear an old queue
    dataQueue = New Queue(Of Double)()
    ' read the num avgs text box. you may want to change on the fly also
    numReadingsToAvg = Integer.Parse(Me.txtReadingsToAvg.Text)
    myComPort.WriteLine("$01MC" & Chr(13))
End Sub

Private Sub myComPort_DataReceived(sender As Object, e As SerialDataReceivedEventArgs) Handles myComPort.DataReceived
    Dim incomingLine As String = myComPort.ReadLine()
    ' DataReceived event happens on its own thread, not the UI
    ' must invoke call back to UI to change properties of controls
    txtRawData.Invoke(Sub() txtRawData.Text = incomingLine)
    Dim incomingValue As String = incomingLine.Remove(0, 3).Trim()
    If Not String.IsNullOrWhiteSpace(incomingValue) Then
        Exit Sub
    Else
        Dim measurement As Double = Double.Parse(incomingValue)
        boxPSIA.Invoke(Sub() boxPSIA.Text = Format(measurement, "##0.000"))
        dataQueue.Enqueue(measurement)
        ' if there are too many items, remove the last one
        If dataQueue.Count > numReadingsToAvg Then
            dataQueue.Dequeue()
        End If
        Dim average As Double = dataQueue.Average()
        ' you need to add this textbox
        anotherTextBox.Invoke(Sub() anotherTextBox.Text = Format(average, "##0.000"))
    End If
End Sub

顺便说一句，Application.DoEvents() 应该很少（从不）使用，因为总是有更好的方法来解决您使用 DoEvents 包扎的任何问题。您的原始示例因在 UI 上运行永无止境的循环而阻塞了 UI 线程。如果您需要运行这样的循环，它应该几乎总是在与 UI 线程不同的线程上运行。在我的示例中，没有循环，时间由端口本身决定。无需在 UI 线程上发生任何这些。

于 2016-10-17T13:53:37.373 回答