11

我有这个 AST

data ExprF r = Const Int | Add   r r
type Expr = Fix ExprF

我想比较

x = Fix $ Add (Fix (Const 1)) (Fix (Const 1))
y = Fix $ Add (Fix (Const 1)) (Fix (Const 2))

但是所有递归方案函数似乎只适用于单一结构

显然我可以使用递归

eq (Fix (Const x)) (Fix (Const y)) = x == y
eq (Fix (Add x1 y1)) (Fix (Add x2 y2)) = (eq x1 x2) && (eq y1 y2)
eq _ _ = False

但我希望可以使用某种 zipfold 功能。

4

2 回答 2

6

作用于单个参数的递归方案就足够了，因为我们可以从方案应用程序返回一个函数。在这种情况下，我们可以Expr -> Bool从上的方案应用程序返回一个函数Expr。为了有效的相等检查，我们只需要paramorphisms：

{-# language DeriveFunctor, LambdaCase #-}

newtype Fix f = Fix (f (Fix f))
data ExprF r = Const Int | Add r r deriving (Functor, Show)
type Expr = Fix ExprF

cata :: Functor f => (f a -> a) -> Fix f -> a
cata f = go where go (Fix ff) = f (go <$> ff)

para :: Functor f => (f (Fix f, a) -> a) -> Fix f -> a
para f (Fix ff) = f ((\x -> (x, para f x)) <$> ff)

eqExpr :: Expr -> Expr -> Bool
eqExpr = cata $ \case
  Const i -> cata $ \case
    Const i' -> i == i'
    _        -> False
  Add a b -> para $ \case
    Add a' b' -> a (fst a') && b (fst b')
    _         -> False

当然，cata在以下方面可以轻松实现para：

cata' :: Functor f => (f a -> a) -> Fix f -> a
cata' f = para (\ffa -> f (snd <$> ffa)

从技术上讲，几乎所有有用的功能都可以使用 来实现cata，但它们不一定是有效的。我们可以para使用cata：

para' :: Functor f => (f (Fix f, a) -> a) -> Fix f -> a
para' f = snd . cata (\ffa -> (Fix (fst <$> ffa) , f ffa))

但是，如果我们使用para'ineqExpr我们会得到二次复杂度，因为para'输入的大小始终是线性的，而我们可以使用在恒定时间内para查看最高值。Expr

于 2016-07-23T16:15:59.513 回答
4

（此响应使用数据修复库，因为我无法编译递归方案。）

我们可以将两棵树的差异建模为基于原始函子的“差异函子”的变形或展开。

考虑以下类型

data DiffF func r = Diff (Fix func) (Fix func) 
                  | Nodiff (func r)
                  deriving (Functor)

type ExprDiff = Fix (DiffF ExprF)

这个想法是，只要它保持相等，ExprDiff它将遵循原始树的“公共结构” ，但是在遇到差异的那一刻，我们切换到叶子，它存储我们发现不同的两个子树。ExprDiff

实际的比较函数是：

diffExpr ::  Expr -> Expr -> ExprDiff  
diffExpr e1 e2 = ana comparison (e1,e2)
    where
    comparison :: (Expr,Expr) -> DiffF ExprF (Expr,Expr)
    comparison (Fix (Const i),Fix (Const i')) | i == i' = 
        Nodiff (Const i')
    comparison (Fix (Add a1 a2),Fix (Add a1' a2')) = 
        Nodiff (Add (a1,a1') (a2,a2'))
    comparison (something, otherthing) = 
        Diff something otherthing

变形的“种子”是我们要比较的一对表达式。

如果我们只是想要一个谓词Expr -> Expr -> Bool，我们可以稍后使用检测分支存在的 catamorphism Diff。

于 2016-07-24T10:35:41.240 回答