0

我被告知要创建一个兄弟谓词来确定兄弟是否有兄弟姐妹。Brother(B, S) :-. 我知道您需要确定他们是否有相同的父母，但我不知道该怎么做。

father(dan,phil).
father(dan,jack).
father(dan,christine).
father(phil,kenton).
father(phil,shula).
father(phil,david).
father(phil,elizabeth).
father(jack,lillian).
father(jack,tony).
father(jack,jenny).
father(tony,tommy).
father(tony,helen).
father(tony,john).
father(roger,adam).
father(roger,debbie).
father(brian,kate).
father(david,pip).
father(david,josh).
father(mark,daniel).

mother(doris,phil).
mother(doris,jack).
mother(doris,christine).
mother(jill,kenton).
mother(jill,shula).
mother(jill,david).
mother(jill,elizabeth).
mother(peggy,lillian).
mother(peggy,tony).
mother(peggy,jenny).
mother(pat,tommy).
mother(pat,helen).
mother(pat,john).
mother(jenny,adam).
mother(jenny,debbie).
mother(jenny,kate).
mother(ruth,pip).
mother(ruth,josh).
mother(shula,daniel).

male(dan).
male(phil).
male(jack).
male(kenton).
male(david).
male(tony).
male(brian).
male(roger).
male(mark).
male(john).
male(tommy).
male(adam).
male(daniel).
male(josh).

female(doris).
female(jill).
female(peggy).
female(christine).
female(shula).
female(ruth).
female(elizabeth).
female(lillian).
female(pat).
female(jenny).
female(helen).
female(debbie).
female(kate).
female(pip).

dead(dan).
dead(doris).
dead(jack).
dead(mark).
dead(john).
dead(fred).


parent(X,Y) :-
        father(X,Y); mother(X,Y).

grandfather(X,Y) :-
        father(X,Z), mother(Z,Y).
grandfather(X,Y) :-
        father(X,Z), father(Z,Y).

ancestor(X,Y) :- parent(X,Y).
ancestor(X,Y) :- parent(X,Z), ancestor(Z,Y).

archer(dan).
archer(X) :- father(P,X), archer(P).

这是我拥有的定义父母、祖父等的文档。我需要创建一个兄弟谓词，它作为兄弟（B 是兄弟，S 是兄弟姐妹）。例如兄弟（利亚姆，乔治亚州）。利亚姆是乔治亚的兄弟应该是真的

4

1 回答 1

7

您可以通过首先提供 a 是什么的正式定义来解决您的问题brother(B,S)：

slibing的兄弟B是具有相同和的。 S male/1father/2 Fmother/2 M

现在我们知道了这一点，我们为每个条件写一行或多行。

第一个只是子句的开头：

brother(B,S) :-

现在由于兄弟是 a male/1，我们检查的第一个条件是：

    male(B),

接下来我们要检查它们是否相同father/2。因此我们定义了一个父亲F，并且F必须是 的父亲B，所以我们写：

    father(F,B),

因为那个父亲也必须是他的父亲S，所以我们写道：

    father(F,S),

这同样适用于mother：我们定义一个母亲M并检查这个母亲是两者的母亲，B并且S：

    mother(M,B),
    mother(M,S).

现在把它们放在一起，我们得到：

brother(B,S) :-
    male(B),
    father(F,B),
    father(F,S),
    mother(M,B),
    mother(M,S).

现在的问题是，有了这个谓词，男性将成为他自己的兄弟。如果您不希望这种行为，我们添加一个约束：

一个人不是brother/2他自己。

因此，您必须使用不相等的谓词：

    B \= S.

或完整的谓词：

brother(B,S) :-
    male(B),
    father(F,B),
    father(F,S),
    mother(M,B),
    mother(M,S),
    B \= S.

该谓词生成以下答案：

?- brother(B,S).
B = phil,
S = jack ;
B = phil,
S = christine ;
B = jack,
S = phil ;
B = jack,
S = christine ;
B = kenton,
S = shula ;
B = kenton,
S = david ;
B = kenton,
S = elizabeth ;
B = david,
S = kenton
...
于 2016-03-31T17:34:45.730 回答