1

让我用一组具体的例子来问这个问题。第一个代码 nlines.pl 如下：

#!/usr/local/bin/perl
#########################
# print Hello world n times with n entered by a prompt
#########################

use strict;
use Time::HiRes qw(sleep);

die "Syntax: $0 <prompt> <time2sleep>\n" if ($#ARGV < 1);
my $prompt = $ARGV[0] . '> ';
my $sleepsec = $ARGV[1];        print "$0: Timeout interval: $sleepsec\n";
print $prompt;
while (<STDIN>) {
        chomp;
        last unless /\d+/;
        my $loopCount = $_;
        print "\n$0: Received request for $loopCount lines\n";
        for (my $count = 0; $count != $loopCount ; $count++) {
                Time::HiRes::sleep($sleepsec) if ($sleepsec > 0);
                print "$0 [$count] Hello world\n"
        }
        print $prompt
}
print "Bye bye\n";
exit 0;

$ nlines.pl pp 0.2 生成提示符“pp>”，当输入“6”时，以 0.2 秒的时间间隔打印 6 次“Hello world”（仅当间隔为 +ve 数字时）。非数字输入使您脱离循环，而行数为负数会导致无限循环。工作正常！

现在，考虑第二个脚本 - “expnlines.pl”，作为上述脚本的驱动程序。

#!/usr/local/bin/perl
#############################
# expnlines.pl: driver for nlines.pl
#############################

use strict;
use Expect;

die "Syntax: $0 <Count> <SleepSec>\n" if ($#ARGV < 1);
my $count = $ARGV[0];
my $child = 'nlines.pl';
my $prompt = 'CountOfLines';
my $ex = Expect->new;
$ex->raw_pty(1);
$ex->spawn ($child, $prompt, $ARGV[1]);
$ex->expect (1, $prompt) or die "$0: No prompt from $child\n";
print "$0: Sending $count\n";
$ex->send($count . "\n");
$ex->expect (2, $prompt) or die "\n$0: Expect timed out for $count\n";
print "\n$0: Received prompt back from expect\n";
exit 0;

如果我们将其作为“expnlines.pl 4 0.2”运行，它可以正常工作。“expnlines.pl -1 0.3”（或其他任何超时）也可以。对于 linecount 的 -ve #，第一个脚本进入无限循环，但预期超时。但是，“expnlines.pl -1 0”无法停止无限循环（在那 2 秒之后），我无法弄清楚如何让期望中断这个循环。

有什么建议么？TIA。

顺便说一句，在我的现实世界中，我无法控制“nlines.pl”的等效二进制文件。我的脚本是“expnlines.pl”，我使用期望作为二进制驱动程序，具有不同的参数。当子进程运行无限循环时，我需要一些机制来检测和停止它，我不知道如何。欣赏回复。

4

1 回答 1

1

超时后，您可以使用hard_close, 关闭命令（或者soft_close如果您需要很好，并且可以等待它使用的额外时间），以终止它，然后无限循环。

代替

$ex->expect (2, $prompt) or die "\n$0: Expect timed out for $count\n";

你可以做类似的事情

if (!$ex->expect(2, $prompt)) {
    print "\n$0: Expect timed out for $count, closing\n";
    $ex->hard_close();
}
else {
    print "\n$0: Received prompt back from expect\n";
}
于 2016-03-17T06:38:47.040 回答