0

所以我的问题可能比这大一点，但我不确定。我正在为使用 Loader 对象动态加载图像的客户端创建自定义 Flash 照片查看器。它获取服务器上指定目录中的文件夹名称并调用 php 页面（使用 URLRequest）来获取文件夹的可用内容。然后它从那个数组中加载它。

问题是：它在我的机器和我测试过的每台机器上都可以正常工作，但在我客户的机器或他客户的某些机器上却不能正常工作。屏幕底部的加载器栏没有开始填充，这意味着图像甚至没有开始加载，状态栏表示它继续等待服务器，但永远不会完成等待。这在单台机器上是一致的，但在不同机器上会有所不同。

我添加了诊断程序（我为跟踪某些变量和收集错误而创建的自定义类）以捕获任何错误，但它在我的客户机器上没有报告任何内容。我已经添加了 Flash 版本检查代码，所以低版本搞砸的可能性已经消失了......

我想我的问题是，有什么（安全、环境等）我可以忽略的，不允许请求对象或某些东西在某些机器上工作？我一直在扯我的头发试图弄清楚这一点！

我的代码（相关部分）：

    public static const LOADLIMIT:int = 4;

    public var paramObj:Object;
    private var imageRequests:Vector.<URLRequest>;
    private var loaderObj:Vector.<Loader>;
    private var nextToLoad:int = -1;

    //...

    public function Player(){
        //...
        paramObj = loaderInfo.parameters;
            if (!paramObj.root) paramObj.root = "http://site.com/images/";
            paramObj.imgloc = paramObj.imgloc;
            var res = bootstrapImages(paramObj.imgloc);
            if (res is String){
                loadErrorMsg.text = res;
                loadErrorMsg.visible = true;
                log.log(res);
            }
        //...
    }

    private function bootstrapImages(imgloc:String):*{
        try{
        if (!imgloc) return "No image location specified"; 

        var req:URLRequest = new URLRequest(paramObj.root+"getdirlist.php?name="+imgloc);
        var loader:URLLoader = new URLLoader();
        loader.addEventListener(Event.COMPLETE, directoryLoaded);
        loader.addEventListener(IOErrorEvent.IO_ERROR, function(ex:IOError){
            loadErrorMsg.text = "Error retreiving album data.";
            loadErrorMsg.visible = true;
            log.log(ex);
        });
        loader.load(req);
        } catch (ex:Error){
            log.log(ex); throw ex;
        }
    }

    private function directoryLoaded(e:Event){
        try{
        //directory will come down as a json array
        trace(e.target.data);
        try {
            var items:Array = JSON.decode(e.target.data);
        } catch (ex:Error){
            trace (ex.getStackTrace());
            loadErrorMsg.text = "Error parsing album data.";
            loadErrorMsg.visible = true;
            log.log(ex);
            return;
        } 

        if (items.length == 0){
            loadErrorMsg.text = "Invalid album name";
            loadErrorMsg.visible = true;
            log.log("Items length is 0.");
            return;
        }

        imageRequests = new Vector.<URLRequest>();
        loaderObj = new Vector.<Loader>();
        for each(var item:String in items){
            imageRequests.push(new URLRequest(paramObj.root+"coffeeimages/"+paramObj.imgloc+"/"+item));
            loaderObj.push(null);
        }

        //...show UI...

        for (var i:int = 0; i < LOADLIMIT; i++){
            imageLoaded(null);
        }
        } catch (ex:Error){
            log.log(ex); throw ex;
        }
    }

    private function imageLoaded(e:Event){
        try{
        //if this was called as a result of the load event, start the slideshow! :D
        if (e != null && e.target != null) {
            //stage.addChild((e.target as LoaderInfo).loader);
            trace(loaderObj[0]);
            if (loaderObj[0] != null && //if the first image is loaded
                loaderObj[0].contentLoaderInfo.bytesLoaded >= loaderObj[0].contentLoaderInfo.bytesTotal){ 
                trace(loaderObj[0].contentLoaderInfo.bytesLoaded, loaderObj[0].contentLoaderInfo.bytesTotal);
                loadErrorMsg.visible = false;
                playSlideshow(true);
            }
        }
        trace((e)?e.target:null, loaderObj);
        nextToLoad++;
        if (nextToLoad >= imageRequests.length) return;

        var r:URLRequest = imageRequests[nextToLoad];
        var l:Loader = new Loader();
        l.contentLoaderInfo.addEventListener(Event.COMPLETE, imageLoaded);
        l.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, function(ex:ErrorEvent){
            loadErrorMsg.text = "Error parsing image data.";
            loadErrorMsg.visible = true;
            log.log(ex);
        });
        l.load(r);
        loaderObj[nextToLoad] = l;
        log.addObjectWatch(l);
        } catch (ex:Error){
            log.log(ex); throw ex;
        }
    }

此外，这是该网站上的播放器。Ctrl+Alt+Home 调出我的诊断面板。请告诉我它是否对您也不起作用，所以我可以更担心这个......：/谢谢。

编辑：我添加了更多调试信息。事实证明，在无法加载它的计算机上，它们在尝试引导专辑信息时会返回 HTTP 状态 0。我不知道那是什么意思...

4

3 回答 3

1

所以，问题是它请求的 URL 的问题......

我的客户正在输入“www.site.com”，而我的代码正在请求“site.com”。对于 Adob​​e，这是一个跨站点请求，默认情况下是不允许的。一种解决方案（可能也是最简单的一种）是将一个名为“crossdomain.xml”的文件添加到网站的根文件夹中。Flash 在发出请求时会查找此文件。一个对我有用的例子如下：

//crossdomain.xml
<?xml version="1.0"?>
<!DOCTYPE cross-domain-policy SYSTEM "http://www.adobe.com/xml/dtds/cross-domain-policy.dtd">

<cross-domain-policy>
    <allow-access-from domain="*.site.com" secure="false"/>
</cross-domain-policy>

其他解决方案包括重定向到两者之一（“site.com”重定向到“www.site.com”），或者进行 url 重写，或者获取他们输入的 url。

于 2010-09-06T23:26:43.263 回答
0

我注意到一些事情，你只在监听 Event.COMPLETE 和 IOErrorEvent.IO_ERROR。我建议还监听 HTTPStatusEvent.HTTP_STATUS、Event.OPEN，虽然我没有添加这些，但如果你仍然没有得到任何结果，它们可能会提供有用的信息。

如果您只加载图像而不访问其内容，则不需要 LoaderContext 对象，因此（安全性）确实不应该成为问题。你绝对应该在 imageLoaded 中分离出你的逻辑，这样它就不是你的加载器的发起者和完成处理程序。

无论如何，不​​知道这是否对您有用，但我已经使您的代码更具可读性，并重新编写了一些毫无意义的东西。

public static const LOADLIMIT:int = 4;

private var paramObj:Object;
private var imageRequests:Vector.<URLRequest>;
private var loaderObj:Vector.<Loader>;
private var nextToLoad:int = -1;

public function Player(){
    paramObj = loaderInfo.parameters;

    //what is this all about, your backup URL is useless?
    if (!paramObj.root) {
        paramObj.root = "http://site.com/images/";
    }

    var res = bootstrapImages();
    if (res.length > 0){
        loadErrorMsg.text = res;
        loadErrorMsg.visible = true;
        //log.log kills me
        log.log(res);
    }
}

private function bootstrapImages():String {
    try {
        var req:URLRequest = new URLRequest(paramObj.root + "getdirlist.php?name=" + paramObj.imgloc);
        var loader:URLLoader = new URLLoader();
        loader.addEventListener(Event.COMPLETE, directoryLoaded);
        loader.addEventListener(IOErrorEvent.IO_ERROR, dataIOError);
        loader.load(req);
    } catch (ex:Error) {
        log.log(ex);
    }
    return "";
}

private function directoryLoaded(e:Event):void{
    trace(e.target.data);
    try {
        var items:Array = JSON.decode(e.target.data);
    } catch (ex:Error){
        trace (ex.getStackTrace());
        loadErrorMsg.text = "Error parsing album data.";
        loadErrorMsg.visible = true;
        log.log(ex);
        return;
    } 

    if (items.length == 0){
        loadErrorMsg.text = "Invalid album name";
        loadErrorMsg.visible = true;
        log.log("Items length is 0.");
        return;
    }

    imageRequests = new Vector.<URLRequest>();
    loaderObj = new Vector.<Loader>();
    for each(var item:String in items){
        imageRequests.push(new URLRequest(paramObj.root+"coffeeimages/"+paramObj.imgloc+"/"+item));
        loaderObj.push(new Loader());
    }

    for (var i:int = 0; i < LOADLIMIT; i++){
        loadNextImage();
    }
}

private function loadNextImage():void {
    nextToLoad++;
    if (nextToLoad < imageRequests.length) {
        loaderObj[nextToLoad].contentLoaderInfo.addEventListener(Event.COMPLETE, imageLoaded);
        loaderObj[nextToLoad].contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, dataIOError);
        try {
            loaderObj[nextToLoad].load(imageRequests[nextToLoad]);
        }
        catch (e:Error) {
            log.log(ex);
        }
        log.addObjectWatch(loaderObj[nextToLoad]);
    }
}

private function dataIOError(e:IOError):void {
    loadErrorMsg.text = "IOError: " + e.errorID + " - " + e.name + ", " + e.message;
    loadErrorMsg.visible = true;
    log.log(ex);
}

private function imageLoaded(e:Event){
    //Start the slideshow if the first image has loaded
    loadNextImage();
    if (e.target == loaderObj[0]) {
        trace(loaderObj[0].contentLoaderInfo.bytesLoaded, loaderObj[0].contentLoaderInfo.bytesTotal);
        loadErrorMsg.visible = false;
        playSlideshow(true);
    }
}

编辑：您可能只是希望完全废弃您的加载代码，而是使用Bulk Loader

于 2010-08-24T05:29:42.087 回答
0

我喜欢上面提到的 crossdomain.xml 解决方案，但我们在客户端 PC 上遇到了类似的问题。问题是 adblocker 浏览器插件阻止了 actionscript 的 URLRequest。我们目前正在寻找解决方案。

于 2012-09-10T08:03:16.247 回答