这个答案类似于 Stefan K 的方法，但适用于 Java 10 和 Gradle 4.6，并且与 Maven 插件 cxf-codegen-plugin 大致相同。
此解决方案基于2013 年 mooregreatsoftware.com的博客文章Generated Files in Gradle 。它的不同之处在于
- 它通过在 Groovy 中
commons-io:commons-io实现一个非常简单的内联来避免构建脚本依赖TeeOutputStream
- 它已更改为与 Java 9、10 和可能的 11 一起使用。
主要动机之一是JEP 320：删除为 Java 11 计划的 Java EE 和 CORBA 模块--add-modules java.se.ee。有一些方法可以通过使用类似JEP 320 状态的东西来使其与 Java 9 和 Java 10 一起工作：
由于 Java EE 技术的独立版本很容易从第三方站点（例如 Maven Central）获得，因此 Java SE 平台或 JDK 不需要包含它们。
这里有两个代码清单，第一个是完成工作的更紧凑的代码。第二个代码清单是相同的代码，但带有注释并注释掉了您可能想要覆盖的传递依赖项。
较短的版本
plugins {
id 'java'
id 'project-report'
}
repositories {
jcenter()
}
sourceCompatibility = 10
targetCompatibility = 10
configurations {
wsdl2java
}
dependencies {
compile 'org.apache.cxf:cxf-rt-frontend-jaxws:3.2.2'
compile 'org.apache.cxf:cxf-rt-transports-http:3.2.2'
compile 'javax.xml.ws:jaxws-api:2.3.0'
compile 'javax.jws:jsr181-api:1.0-MR1'
compile 'javax.xml.bind:jaxb-api:2.3.0'
compile 'javax.activation:javax.activation-api:1.2.0'
compile 'javax.annotation:javax.annotation-api:1.3'
wsdl2java 'javax.xml.bind:jaxb-api:2.3.0'
wsdl2java 'com.sun.xml.bind:jaxb-ri:2.3.0'
wsdl2java 'com.sun.xml.bind:jaxb-xjc:2.3.0'
wsdl2java 'com.sun.xml.bind:jaxb-core:2.3.0'
wsdl2java 'com.sun.xml.bind:jaxb-impl:2.3.0'
wsdl2java 'javax.activation:javax.activation-api:1.2.0'
wsdl2java 'javax.annotation:javax.annotation-api:1.3'
wsdl2java 'javax.xml.ws:jaxws-api:2.3.0'
wsdl2java 'javax.jws:jsr181-api:1.0-MR1'
wsdl2java 'org.apache.cxf:cxf-tools-wsdlto-core:3.2.2'
wsdl2java 'org.apache.cxf:cxf-tools-wsdlto-frontend-jaxws:3.2.2'
wsdl2java 'org.apache.cxf:cxf-tools-wsdlto-databinding-jaxb:3.2.2'
}
def wsdl2java = task generateJavaFromWsdl(type: JavaExec) {
String wsdl = 'src/main/resources/some.wsdl'
String genSrcDir = "${projectDir}/build/generated-sources/cxf-ws"
inputs.file wsdl
outputs.dir genSrcDir
classpath configurations.wsdl2java
main "org.apache.cxf.tools.wsdlto.WSDLToJava"
args '-encoding', 'UTF-8', '-d', genSrcDir, wsdl
OutputStream baos = new ByteArrayOutputStream()
errorOutput = new OutputStream() {
void write(int b) {System.err.write(b); baos.write(b) }
void flush() { System.err.flush(); baos.flush() }
void close() { System.err.close(); baos.close() }
}
doLast {
def str = baos.toString()
if (str.contains('Usage : wsdl2java') || str.contains('WSDLToJava Error')) {
throw new TaskExecutionException(tasks[name],
new IOException('Apache CXF WSDLToJava has failed. Please see System.err output.'))
}
}
}
compileJava.dependsOn += wsdl2java
sourceSets.main.java.srcDirs = ['src/main/java', 'build/generated-sources/cxf-ws']
评论版本
plugins {
id 'java'
id 'project-report' // really useful to find out what gets pulled in transitively
}
repositories {
jcenter()
}
// works with 1.8, 9, 10 and should be working with 11.
sourceCompatibility = 10
targetCompatibility = 10
configurations {
wsdl2java
}
dependencies {
compile 'org.apache.cxf:cxf-rt-frontend-jaxws:3.2.2'
compile 'org.apache.cxf:cxf-rt-transports-http:3.2.2'
compile 'javax.xml.ws:jaxws-api:2.3.0'
compile 'javax.jws:jsr181-api:1.0-MR1'
compile 'javax.xml.bind:jaxb-api:2.3.0'
//
// You might have these already imported due to other dependencies, but
compile 'javax.activation:javax.activation-api:1.2.0'
compile 'javax.annotation:javax.annotation-api:1.3'
// ===== Apache CXF dependencies for the command line generation of java files
//
// http://openjdk.java.net/jeps/320
// this JEP lists out exactly which dependencies are required to avoid using
// deprecated Java EE modules.
//
// JAXB dependencies that Apache CXF cxf-tools-wsdlto-databinding-jaxb uses directly
// we list them here all so we have a single version 2.3.0 among all of them
wsdl2java 'javax.xml.bind:jaxb-api:2.3.0'
wsdl2java 'com.sun.xml.bind:jaxb-ri:2.3.0'
wsdl2java 'com.sun.xml.bind:jaxb-xjc:2.3.0'
wsdl2java 'com.sun.xml.bind:jaxb-core:2.3.0'
wsdl2java 'com.sun.xml.bind:jaxb-impl:2.3.0'
//
// Other stuff that Apache CXF assume to be available from the JDK
wsdl2java 'javax.activation:javax.activation-api:1.2.0'
wsdl2java 'javax.annotation:javax.annotation-api:1.3'
wsdl2java 'javax.xml.ws:jaxws-api:2.3.0'
wsdl2java 'javax.jws:jsr181-api:1.0-MR1'
//
// This is the big lazy solution and it puts the whole jaxws-ri stack on the classpath
// As this is just the isolated classpath for wsdl2java you might not care.
// This might be useful when you have missing dependencies with the above reduceded
// list of dependencies. the Gradle plugin "project-report" has a task "projectReport"
// that can really help
//wsdl2java('com.sun.xml.ws:jaxws-ri:2.3.0') {
//
// this dependency is broken in 2.3.0. This articaft is simply not on mavenCentral
// or jcenter. It looks like the correct one would be
// 'org.eclipse.persistence:commonj.sdo:2.1.1' but we are not in the postion
// to change this. As we are not interested in any JPA integration anyways we
// just skip it for now.
//exclude group: 'commonj.sdo', module: 'commonj.sdo'
//}
wsdl2java 'org.apache.cxf:cxf-tools-wsdlto-core:3.2.2'
wsdl2java 'org.apache.cxf:cxf-tools-wsdlto-frontend-jaxws:3.2.2'
wsdl2java 'org.apache.cxf:cxf-tools-wsdlto-databinding-jaxb:3.2.2'
}
//
// there is no real Gradle plugin here, we rather use Gradle's build in task JavaExec
// which is the Gradle way to call an external java program.
def wsdl2java = task generateJavaFromWsdl(type: JavaExec) {
String wsdl = 'src/main/resources/some.wsdl'
String genSrcDir = "${projectDir}/build/generated-sources/cxf-ws"
inputs.file wsdl
outputs.dir genSrcDir
classpath configurations.wsdl2java
main "org.apache.cxf.tools.wsdlto.WSDLToJava"
// you can add any of the Apache CXF command line parameters here
// http://cxf.apache.org/docs/wsdl-to-java.html
args '-encoding', 'UTF-8', '-d', genSrcDir, wsdl
// you can set jvmArgs as well. F.i. proxy
//jvmArgs "-Dhttp.proxyHost=10.10.10.10", "-Dhttp.proxyPort=8080"
OutputStream baos = new ByteArrayOutputStream()
errorOutput = new OutputStream() {
// extrem simplified TeeOutputStream to avoid dependency on Apache commons-io
void write(int b) {System.err.write(b); baos.write(b) }
// no need to call flush and close on a ByteArrayOutputStream, but lets be safe
void flush() { System.err.flush(); baos.flush() }
void close() { System.err.close(); baos.close() }
}
// We inspect the collected logging an throw an TaskExecutionException if necessary.
doLast {
String str = baos.toString()
if (str.contains('Usage : wsdl2java') || str.contains('WSDLToJava Error')) {
throw new TaskExecutionException(tasks[name],
new IOException('Apache CXF WSDLToJava has failed. Please see System.err output.'))
}
}
}
// we hook the custom task wsdl2java into the Gradle tasks graph / life cycle
compileJava.dependsOn += wsdl2java
// usually we want to access the generated code in the main source set and IDE's
sourceSets.main.java.srcDirs = ['src/main/java', 'build/generated-sources/cxf-ws']