sas - 变量中具有特定参数的 SAS 回归

Question

下午好。

是否可以使用细节回归变量，例如 Y = X1（Q1 和 Q3 之间）X2（X2 > 100）X3？我不希望回归 X1 或 X2 中的所有数据，只希望回归我确定的参数中的数据。

如何回归分位数 Q3 和 Q4 之间的所有变量？

我以正确的方式接近这个吗？

谢谢您的支持。

 *Regression output;
 ods graphics on;
 proc reg data=mydata PLOTS(ONLY)=(DIAGNOSTICS FITPLOT RESIDUALS);
 model Y = X1 X2 X3; 
 title 'Working Regression Model';
 run;
 ods graphics off;

Answer 1

如果您只想使用部分数据进行回归，您可以自己过滤掉proc reg它：

proc reg data=mydata (where=(X1 Between Q1 and Q3 and X2 > 100))
    PLOTS(ONLY)=(DIAGNOSTICS FITPLOT RESIDUALS);
model Y = X1 X2 X3; 

即 ifQ1和Q3are 中的字段myData。如果没有，您可以为它们创建宏变量。例如

%let Q1 = 50;
%let Q3 = 250;
proc reg data=mydata (where=(X1 Between &Q1. and &Q3. and X2 > 100))
    PLOTS(ONLY)=(DIAGNOSTICS FITPLOT RESIDUALS);
model Y = X1 X2 X3; 

这是如果您预先知道 Q1 和 Q3。

如果Q1andQ3是另一个数据集中的字段，proc sqlwithselect Q1, Q3. into :Q1, :Q3或 data step withcall symput('Q1', Q1); call symput('Q3', Q3);可以完成这项工作。

阅读您的评论后进行编辑，解释Q1等是分位数：

以下示例可能包含您需要的所有构建块

ods graphics on;
proc means data=SASHELP.CLASS noprint;
    var Height Weight;
    output out=CLASS_Q
        P25(Height Weight)=Height_Q1 Weight_Q1
        P75(Height Weight)=Height_Q3 Weight_Q3;
run;
data _NULL_;
    set CLASS_Q;
    call symput('Height_Q1', Height_Q1);
    call symput('Height_Q3', Height_Q3);
    call symput('Weight_Q1', Weight_Q1);
    call symput('Weight_Q3', Weight_Q3);
run;
%put _user_; *just to debug;
proc reg data=SASHELP.CLASS 
    (where=(Height Between &Height_Q1. and &Height_Q3. and Weight > &Weight_Q1.))
    PLOTS(ONLY)=(DIAGNOSTICS FITPLOT RESIDUALS);
    model Age = Height Weight;
run;