2

我在这里有一个 Prolog 问题，我试图将独特的机场加入列表，但我的谓词没有按预期工作。

not_member(C, []).
not_member(C, [H|L]) :-
   not_member(C, L),
   C \== H.

path(X, Y, [X,Y]) :-
   flight(X, Y, _, _, _, _).
path(X, Y, [X,P]) :-
   not_member(Z, P), 
   flight(X, Z, _, _, _, _),
   flight(Z, Y, _, _, _, _), 
   path(Z, Y, P).

具有预期答案的示例查询：

?- path(dublin, rome, L)
L = [dublin, rome] ;
L = [dublin, paris, rome] ...

如果您需要事实让我知道，我们将不胜感激。谢谢！

4

1 回答 1

0

问题不在于 (\==)/2。问题是未实例化的 P 会使 not_member/2 循环。所以你需要一个带有四个参数的谓词 path/4 ：

:- use_module(library(basic/lists)).
path(_, X, L, _) :- member(X, L), !, fail.
path(X, X, L, [X|L]).
path(Y, X, L, R) :-
   flight(Z, X),
   path(Y, Z, [X|L], R).

上述谓词从目的地机场向后搜索，因此我们不需要反转结果列表。这是一个示例数据库：

flight(zurich, frankfurt).
flight(frankfurt, zurich).
flight(zurich, munich).
flight(munich, zurich).
flight(munich, frankfurt).
flight(frankfurt, munich).

这是一个运行示例：

Jekejeke Prolog 2, Runtime Library 1.2.5
(c) 1985-2017, XLOG Technologies GmbH, Switzerland

?- path(zurich, frankfurt, [], L).
L = [zurich,frankfurt] ;
L = [zurich,munich,frankfurt] ;
No
于 2018-01-27T16:41:29.497 回答