4

基本上我想要实现的是当用户在应用程序的某个部分根据需要更改屏幕旋转时，我有这个适用于 Andriod，我不明白为什么它不应该适用于 iOS

procedure TForm1.Button1Click(Sender: TObject);
var
  ScreenService: IFMXScreenService;
  OrientSet: TScreenOrientations;
begin
    if TPlatformServices.Current.SupportsPlatformService(IFMXScreenService, IInterface(ScreenService)) 
    then
    begin
        OrientSet := [TScreenOrientation.soLandscape];//<- Break point set here and line is executed
        ScreenService.SetScreenOrientation(OrientSet);
    end;
end;

取自这里：如何在delphi xe5 Firemonkey中使用android开发防止屏幕旋转

ScreenService.SetScreenOrientation 被执行并且不会引发异常但方向没有改变，我还在 Project>Options>Application>Orientation 中设置了Enable custom orientation但这也没有任何效果。

对我来说奇怪的是，如果不支持它，那么不应该这样吗

if TPlatformServices.Current.SupportsPlatformService(IFMXScreenService, IInterface(ScreenService))

返回假？甚至没有进入开始

在我将其设置为横向后，我添加了一个测试按钮来检查屏幕方向

if TPlatformServices.Current.SupportsPlatformService(IFMXScreenService, IInterface(ScreenService)) 
then
begin
    case ScreenService.GetScreenOrientation of
        TScreenOrientation.Portrait: ShowMessage('Portrait');
        TScreenOrientation.Landscape: ShowMessage('landscape');
        TScreenOrientation.InvertedPortrait: ShowMessage('Inverted-Portrait');
        TScreenOrientation.InvertedLandscape: ShowMessage('Inverted-Landscape');
        else ShowMessage('not set');
    end;
end;

如果它在设置为横向后是纵向的，它仍然会显示纵向

更新1：我也尝试过改变

OrientSet := [TScreenOrientation.soLandscape] // <- Deprecated

到

OrientSet := [TScreenOrientation.Landscape]

但行为仍然相同

4

1 回答 1

5

好的，这次轮换让我深入研究了 iOS API，以了解 iOS 如何管理方向。

因为您不能在 iOS 中伪造旋转或强制设备在 iOS 中的特定设备方向，所以您需要考虑很多方向

  • 设备方向
  • 状态栏方向
  • UIViewcontroller 方向

无法强制或更改设备方向，这将始终显示您的设备现在所处的方向。

但是，状态栏方向始终具有setStatusBarOrientation您可以调用的过程并指定您想要的方向，但这被标记为已弃用，因此无法正常工作，但是当我调用该函数时没有遇到外部异常，这说明它还在那里，只是没有工作。

然后我读到了这个：

setStatusBarOrientation:animated: 方法并未完全弃用。它现在仅在最顶层全屏视图控制器的 supportedInterfaceOrientations 方法返回 0 时才有效

然后我决定试试这个

Application.FormFactor.Orientations := []; //the supportedInterfaceOrientations returns 0
App := TUIApplication.Wrap(TUIApplication.OCClass.sharedApplication);
win := TUIWindow.Wrap(App.windows.objectAtIndex(0));
App.setStatusBarOrientation(UIInterfaceOrientationLandscapeLeft);

它适用于状态栏方向的变化，但如上所述，该协议已被弃用，因此在某个阶段它可以/将会消失，这将不再有效。

但这仅改变了状态栏和所有警报视图等的旋转，但在我想要更改为横向的情况下，rootviewcontroller 中的实际内容仍然在纵向中。

然后我想如果我在 Delphi 中会去 Application->Orientation-> Enable custom rotation and say landscape only then the App will only display in landscape,它做得很好，因为当创建表单然后rootViewcontroller被设置为supportedInterface返回的方向只是横向，而 Viewcontroller 转到横向。

因为当您的设备更改设备方向时，会根据 Viewcontroller 支持的接口方向评估方向，如果不支持方向，则根本不会旋转。

但是，当分配了新的 rootviewcontroller 时，必须更新 GUI 以显示 Viewcontrollers 支持的方向，考虑到这一点，这是我的修复/hack，将您的应用程序的方向更改为您想要的方向。

TL;博士

Uses: iOSapi.UIKit; 

procedure ChangeiOSorientation(toOrientation: UIInterfaceOrientation;
possibleOrientations: TScreenOrientations);
var
    win : UIWindow;
    App : UIApplication;
    viewController : UIViewController;
    oucon: UIViewController;
begin
    Application.FormFactor.Orientations := []; //Change supported orientations
    App := TUIApplication.Wrap(TUIApplication.OCClass.sharedApplication);
    win := TUIWindow.Wrap(App.windows.objectAtIndex(0)); //The first Windows is always the main Window

    App.setStatusBarOrientation(toOrientation);
    {After you have changed your statusbar orientation set the
    Supported orientation/orientations to whatever you need}
    Application.FormFactor.Orientations := possibleOrientations;
    viewController := TUIViewController.Wrap(TUIViewController.alloc.init);//dummy ViewController
    oucon := TUIViewController.Wrap(TUIViewController.alloc.init);
    {Now we are creating a new Viewcontroller now when it is created
     it will have to check what is the supported orientations}
    oucon := win.rootViewController;//we store all our current content to the new ViewController
    Win.setRootViewController(viewController);
    Win.makeKeyAndVisible;// We display the Dummy viewcontroller

    win.setRootViewController(oucon);
    win.makeKeyAndVisible; 
    {And now we Display our original Content in a new Viewcontroller 
     with our new Supported orientations} 
end;

你现在要做的就是打电话ChangeiOSorientation(toOrientation,possibleOrientations)

如果您希望它转到纵向但可以选择横向

 ChangeiOSorientation(UIInterfaceOrientationPortrait,[TScreenOrientation.Portrait,TScreenOrientation.Landscape,TScreenOrientation.InvertedLandscape]);

这正在处理

  • 德尔福 10 西雅图
  • 运行 iOS 9.0 的 iPhone 5
  • PA服务器17.0
  • Xcode 7.1
  • iPhoneOS 9.1 SDK
于 2015-11-10T13:26:35.300 回答