-1

我正在使用XML::Simple和XML::Dumper。我很清楚围绕前一个模块的问题。如果我可以使用替代库，我会的。

我想要实现的是加载 XML，然后将行附加到它。这是我在脚本运行之前的 XML 结构。

<person>
  <appearance>
     <param name="height" value="6,3"/>
  </appearence>
</person>

脚本，或者我打算编写的代码，应该从文件中加载这个 XML，然后将一个<param>元素附加到<appearence>. 我已经尝试使用此代码：

use warnings;

use XML::Simple;
use XML::Dumper;

my $xml = XMLin('xml_import.xml');

$xml->{appearence} .= qq{<param name="age" value="22" />};
my $new_xml = XMLout($xml, noattr => 1, NoEscape => 1);

open(FILE, ">xml_import.xml");
print FILE $new_xml;
close FILE;

不幸的是，输出是这样的：

<opt>
  <appearence>HASH(0x1722190)<param name="age" value="22" /></appearence>
</opt>

我不仅丢失了原始<person>标签，<opt>而且该HASH字符串替换了我假设的现有<param>元素。我已经阅读了文档，XML::Simple但我不知道应该使用什么参数来防止这种情况发生。

4

2 回答 2

2

使用XML::Simple的重点是在代码中使用 Perl 数据结构，而不是 XML。

您的问题正是不鼓励使用该模块的原因。您必须使用ForceArray才能轻松更改父元素中的元素数量，并且您必须清除KeyAttr阻止对name属性的特殊处理。

#!/usr/bin/perl
use warnings;
use strict;

use XML::Simple;

my $xml = << '__XML__';
<person>
  <appearance>
     <param name="height" value="6,3"/>
  </appearance>
</person>
__XML__

my $simple = XMLin($xml, ForceArray => 1,
                         KeepRoot   => 1,
                         KeyAttr    => [],
                  );

push @{ $simple->{person}[0]{appearance}[0]{param} }, { name  => 'age',
                                                        value => 22,
                                                      };
print XMLout($simple, KeepRoot => 1);

为了比较，XML::XSH2中的相同任务是 XML ::LibXML的包装器：

open file.xml ;
my $p := insert element param append /person/appearance ;
set $p/@name 'age' ;
set $p/@value 22 ;
save :b ;
于 2015-10-16T12:53:56.830 回答
0

1.您丢失标签的原因是“XMLin() 通常会丢弃根元素名称。将 'KeepRoot' 选项设置为 '1' 将导致保留根元素名称。”

2.从文件中读取xml后，应将变量作为perl数据结构进行操作。

#! /usr/bin/perl

use strict;
use XML::Simple qw(:strict);
use Data::Dumper;

my $xml = XMLin('xml_import.xml', KeepRoot => 1, KeyAttr => ["param"], ForceArray => ["param"]);
print '-----$xml-----', "\n", Dumper($xml), "\n";

my $new_node = {'name' => 'age', 'value' => '22'};
push $xml->{person}->{appearance}->{param}, $new_node;
print '-----Insert a new node to $xml-----', "\n", Dumper($xml), "\n";

my $new_xml = XMLout($xml, NoAttr => 1, NoEscape => 1, KeepRoot => 1, KeyAttr => []);
print '-----$new_xml-----', "\n", $new_xml, "\n";

或者

#! /usr/bin/perl

use strict;
use XML::Simple qw(:strict);
use Data::Dumper;

my $xml = XMLin('xml_import.xml', KeepRoot => 1, KeyAttr => {param => "+name"}, ForceArray => ["param"]);
print '-----$xml-----', "\n", Dumper($xml), "\n";

my $new_node = {'name' => 'age', 'value' => '22'};
$xml->{person}->{appearance}->{param}->{age} = $new_node;
print '-----Insert a new node to $xml-----', "\n", Dumper($xml), "\n";

my $new_xml = XMLout($xml, NoAttr => 1, NoEscape => 1, KeepRoot => 1, KeyAttr => {param => "+name"});
print '-----$new_xml-----', "\n", $new_xml, "\n";
于 2015-10-16T14:09:43.450 回答