4

在 CLOS 上上课时，我多次遇到相同的模式：

(defclass class-name () 
  ((field-1
      :initarg field-1
      :initform some-value
      :accessor field-1)
   (field-2
      :initarg field-2
      :initform another-value
      :accessor field-2)
   (...)
   (field-n
      :initarg field-n
      :initform n-value
      :accessor field-n)))

（这是否是好的设计是我会随着时间学习的）

我试图用一个宏来解决这个问题，所以我可以打电话说：

(defclass-with-accessors 'class-name
   (('field-1 some-value)
    ('field-2 another-value)
    (...)
    ('field-n n-value)))

我的第一个解决方案（暂时忽略卫生）是分成两个宏：一个用于创建每个字段，另一个用于创建类本身。

使访问器字段的宏似乎是正确的：

(defmacro make-accessor-field (name form)
  `(,name
   :initarg ,(make-keyword name)
   :initform ,form
   :accessor ,name))

但我没有得到正确的主要宏。我的第一次尝试是：

(defmacro defclass-with-accessors (name body)
  `(defclass ,name () \(
     ,(loop for my-slot in body collect
       (make-accessor-field (car my-slot) (cadr my-slot)))))

但这无效，SBCL 在 defmacro 评估时给了我以下错误：

; in: DEFMACRO DEFCLASS-WITH-ACCESSORS
;     (MAKE-ACCESSOR-FIELD (CAR MY-SLOT) (CADR MY-SLOT))
; 
; caught ERROR:
;   during macroexpansion of (MAKE-ACCESSOR-FIELD (CAR MY-SLOT) (CADR MY-SLOT)).
;   Use *BREAK-ON-SIGNALS* to intercept.
;   
;    The value (CAR MY-SLOT)
;    is not of type
;      (OR (VECTOR CHARACTER) (VECTOR NIL) BASE-STRING SYMBOL CHARACTER).
; 
; compilation unit finished
;   caught 1 ERROR condition
STYLE-WARNING:
   redefining COMMON-LISP-USER::DEFCLASS-WITH-ACCESSORS in DEFMACRO

究竟发生了什么？甚至没有定义插槽时，编译器如何判断 (car slot) 的类型？如何继续正确定义此宏？

4

1 回答 1

13

基本错误

这个宏是错误的，因为它不应该是一个宏：

(defmacro make-accessor-field (name form)
  `(,name
   :initarg ,(make-keyword name)
   :initform ,form
   :accessor ,name))

宏形式应扩展为代码。此宏将表单扩展为用于插槽描述的列表。插槽描述不是代码，而是defclass插槽列表的一部分。因此你不能使用这样的宏，因为返回的值应该是代码，而不是槽描述列表。

还有一个通常不会MAKE-在宏名称中使用。这更像是一个约定。MAKE-SOMETHING应该是一个函数。每当您制作某些东西时，都会在运行时创建某些东西，因此它应该是一个函数。有时人们还想将make应用于事物列表，然后再次首选函数。

这也是错误的，因为有一个带括号的符号作为其名称：

(defmacro defclass-with-accessors (name body)
  `(defclass ,name () \(    ;  <-  what is this?
     ,(loop for my-slot in body collect
       (make-accessor-field (car my-slot) (cadr my-slot)))))

这段代码也不是一个好主意，因为引号没有用：

(defclass-with-accessors 'class-name
   (('field-1 some-value)
    ('field-2 another-value)
    (...)
    ('field-n n-value)))

如果您查看defclass，它不需要引用名称。因此，在您的defclass变体中，也不应该有引号。

让我们尝试改进它

来自一些虚构代码库的示例形式：

(defclass-with-accessors foo
   ((bar 10)
    (baz (sin pi)))

MAKE-ACCESSOR-FIELD现在是一个函数：

(defun make-accessor-field (name form)
  `(,name
    :initarg  ,(intern (symbol-name name) "KEYWORD")
    :initform ,form
    :accessor ,name))

新的DEFCLASS-WITH-ACCESSORS：

(defmacro defclass-with-accessors (name slot-descriptions)
  `(defclass ,name ()
     ,(loop for (slot-name form) in slot-descriptions
            collect (make-accessor-field slot-name form))))

让我们检查一下扩展：

macroexpand-1在顶层展开一次表单并pprint以某种自动格式化的方式打印 s 表达式：

CL-USER 12 > (pprint (macroexpand-1 '(defclass-with-accessors foo
                                         ((bar 10)
                                          (baz (sin pi))))))

(DEFCLASS FOO
          NIL
          ((BAR :INITARG :BAR :INITFORM 10 :ACCESSOR BAR)
           (BAZ :INITARG :BAZ :INITFORM (SIN PI) :ACCESSOR BAZ)))

看起来还可以。

于 2015-08-29T07:01:13.153 回答