delphi - Delphi 字典释放

Question

我实现了以下类：

type
  TUtilProcedure = procedure(var AJsonValue: TJSONObject);

  TCallback = class
  private
    FName: string;
    FProcedure: TUtilProcedure;
    FAnnotation: string;
  public
    constructor Create(AName: string; AProcedure: TUtilProcedure; AAnnotation: string); overload;
    constructor Create(ACallback: TCallback); overload;
    property Name: string read FName;
    property Proc: TUtilProcedure read FProcedure;
    property Annotation: string read FAnnotation;
 end;

然后我有一个全局变量：

procedures: TDictionary<string, TCallback>;

在OnFormActivate过程中我初始化procedures变量：

procedures := TDictionary<string, TCallback>.Create();
procedures.Add('something', TCallback.Create('sth', @proc, 'annotation')); 
// ....

然后在OnFormClose我释放它：

procedures.Clear;
procedures.Free;

我的代码会泄漏内存吗？如果是这样，释放的正确方法是dictionary什么？据我所知，迭代不是好主意。

score 11 · Accepted Answer

代码泄漏内存是因为 a 中包含的对象TDictionary不会自动释放。

如果您需要将对象存储在字典中，则采用TObjectDictionary是一种更好的方法。

如果您希望字典中包含的对象自动释放，请doOwnsValues在创建集合实例时使用该标志。

当变量真正是全局的（即在单元var的interfacesection中声明）时，应该在单元本身的initializationand section中创建和销毁。finalization

. . .
var
  procedures: TObjectDictionary<string, TCallback>;
. . .
initialization
  procedures:= TObjectDictionary<string, TCallback>.Create([doOwnsValues]);
finalization
  procedures.Free;

当您的变量属于表单类本身OnCreate时，您应该在表单的事件中创建字典。

. . .
public
  procedures: TObjectDictionary<string, TCallback>;
. . .
procedure TForm1.FormCreate(Sender: TObject);
begin
  procedures:= TObjectDictionary<string, TCallback>.Create([doOwnsValues]);
end;

OnDestroy在表单的事件中释放字典：

procedure TForm1.FormDestroy(Sender: TObject);
begin
  procedures.Free;
end;

此外，如果您希望在不需要类本身的实例的情况下访问属于该类的变量（这在许多编程语言中称为静态变量），您可以将字典声明为 aclass var并可选择通过一个class property; 在这种情况下，最好在class constructor和中创建和销毁集合class destructor。

. . .
TMyClass = class
  private
    class constructor Create;
    class destructor Destoy;
  public
    class var procedures: TObjectDictionary<string, TCallback>;
end;
. . .
class constructor TMyClass.Create;
begin
  procedures := TObjectDictionary<string, TCallback>.Create([doOwnsValues]);
end;

class destructor TMyClass.Destoy;
begin
  procedures.Free;
end;

TCallback = class
  private
    FName: string;
    FProcedure: TUtilProcedure;
    FAnnotation: string;
  public
    constructor Create(AName: string; AProcedure: TUtilProcedure; AAnnotation: string); overload;
    constructor Create(ACallback: TCallback); overload;
    property Name: string read FName;
    property Proc: TUtilProcedure read FProcedure;
    property Annotation: string read FAnnotation;
end;

附带说明一下，TCallback该类不需要指定析构函数，因为它只拥有两个字符串和一个指向过程的指针。因此继承自的默认析构函数TObject就足够了。

delphi - Delphi 字典释放

1 回答 1

Related

Reference