6

chromatic 最近的博客让我对 Moose 子程序感到好奇has。我正在查看 Moose 源代码，并注意到在has子例程中，有一个$meta从@_. 从哪里来$meta？我已经开始涉足各种 Moose 和 Class::MOP 模块。在许多子例程中，它似乎$meta通常作为 中的第一个参数@_，即使它没有专门作为参数传递给它。

编辑：这是has子例程的原始源代码：

sub has {
    my $meta = shift;
    my $name = shift;

    Moose->throw_error('Usage: has \'name\' => ( key => value, ... )')
        if @_ % 2 == 1;

    my %options = ( definition_context => Moose::Util::_caller_info(), @_ );
    my $attrs = ( ref($name) eq 'ARRAY' ) ? $name : [ ($name) ];
    $meta->add_attribute( $_, %options ) for @$attrs;
}
4

3 回答 3

12

您正在寻找的特殊魔法在Moose::Exporter中。您可以has通过 Moose.pm 从此代码中获得该方法：

Moose::Exporter->setup_import_methods(
    with_meta => [
        qw( extends with has before after around override augment )
    ],
    as_is => [
        qw( super inner ),
        \&Carp::confess,
        \&Scalar::Util::blessed,
    ],
);

注意“with_meta”选项setup_import_methods——它以确保传递的第一个参数是元类对象的方式将这些方法导入调用者的命名空间。

扩展 Moose 的各种 MooseX 模块使用 Moose::Exporter 将新符号导入调用者的命名空间。您可以从Moose::Cookbook::Extending::Recipe1开始在食谱中阅读有关此过程的更多信息。

于 2010-07-02T16:07:53.790 回答
6

实际导入包中的不是命名的 has() 子例程，而是插入元对象的闭包。您可以确切地看到这是如何发生的：

$ perl -we'use Data::Dump::Streamer; use Moose; Dump(\&has)'
my ($extra,$sub,@ex_args);
$extra = sub {
       package Moose::Exporter;
       use warnings;
       use strict 'refs';
       Class::MOP::class_of(shift @_);
     };
$sub = sub {
     package Moose;
     use warnings;
     use strict 'refs';
     my $meta = shift @_;
     my $name = shift @_;
     'Moose'->throw_error(q[Usage: has 'name' => ( key => value, ... )]) if @_ % 2 == 1;
     my(%options) = ('definition_context', Moose::Util::_caller_info(), @_);
     my $attrs = ref $name eq 'ARRAY' ? $name : [$name];
     $meta->add_attribute($_, %options) foreach (@$attrs);
   };
@ex_args = ( 'main' );
$CODE1 = sub {
       package Moose::Exporter;
       use warnings;
       use strict 'refs';
       my(@curry) = &$extra(@ex_args);
       return &$sub(@curry, @_);
     };

$CODE1是闭包本身；以上是其中引用的变量。

于 2010-07-02T18:16:46.200 回答
2

molecules在ysth 答案中发表评论：

我不确定 has 子例程是如何转换为这个闭包的，但这肯定显示了导入的 has 的咖喱性质

这是（希望如此！）一个简单的例子，说明如何实现这一点（但我怀疑Moose它是以更复杂和更好的方式实现的！）

元.pm

package Meta;

sub new {
    my $class = shift;
    bless { @_ }, $class;
}

sub has {
    my $meta = shift;
    print "Given => @_ \n";
    print "meta $_ => ", $meta->{$_}, "\n" for keys %$meta;
}

1;

导入.pm

package Import;
use strict;
use warnings;
use Meta;

# some arbitrary meta info!
our $Meta = Meta->new( a => 'A', b => 'B' );

sub import {
    my $caller = caller;

    # import 'has' into caller namespace
    no strict 'refs';
    *{$caller . '::has'} = sub { $Meta->has(@_) };
}

1;

meta_has.pl

use strict;
use warnings;
use Import;

has name => ( is => 'rw', isa => 'Int' );

现在，如果您运行meta_has.pl，您将得到：

# Given => name is rw isa Int 
# meta a => A
# meta b => B

希望有帮助。

/I3az/

于 2010-07-03T09:11:21.520 回答