2

使用此输入 XML：

<?xml version="1.0" encoding="utf-8"?>
<Employees>
   <Employee ID="1">
      <FirstName>Klaus</FirstName>
      <LastName>Salchner</LastName>
   </Employee>
   <Employee ID="2">
      <FirstName>Peter</FirstName>
      <LastName>Pan</LastName>
   </Employee>
</Employees>

你将如何得到这个输出：

<Employees>
    <FirstName>
        <Employee>Klaus</Employee>
        <Employee>Peter</Employee>
    </FirstName>
    <LastName>
        <Employee>Salchner</Employee>
        <Employee>Pan</Employee>
    </LastName>
</Employees>

但是，如果您不知道 Employee 元素中有多少字段 - 但是，我们假设相同的元素（这里是 FirstName 和 LastnName）肯定会出现在每个 Employee 元素中。

我得到的最好的是：

<Employees>
    <xsl:for-each select="*/Employee/.">
        <xsl:value-of select=".">
            <xsl:value-of select="./." />
        </xsl:value-of>
    </xsl:for-each>
</Employees>

我知道那是错误的！

4

3 回答 3

1

这种转变：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:key name="kElsByName" match="Employee/*"
  use="name()"/>

 <xsl:template match="/*">
   <Employees>
     <xsl:for-each select=
      "Employee/*[generate-id()
                 =
                  generate-id(key('kElsByName', name())[1])
                  ]">
       <xsl:element name="{name()}">
         <xsl:for-each select="key('kElsByName', name())">
           <Employee>
             <xsl:value-of select="."/>
           </Employee>
         </xsl:for-each>
       </xsl:element>
     </xsl:for-each>
   </Employees>
 </xsl:template>
</xsl:stylesheet>

当应用于此 XML 文档时（添加<DOB>以使其通用）：

<Employees>
   <Employee ID="1">
      <FirstName>Klaus</FirstName>
      <LastName>Salchner</LastName>
      <DOB>19670823</DOB>
   </Employee>
   <Employee ID="2">
      <FirstName>Peter</FirstName>
      <LastName>Pan</LastName>
      <DOB>19881113</DOB>
   </Employee>
</Employees>

产生想要的结果：

<Employees>
   <FirstName>
      <Employee>Klaus</Employee>
      <Employee>Peter</Employee>
   </FirstName>
   <LastName>
      <Employee>Salchner</Employee>
      <Employee>Pan</Employee>
   </LastName>
   <DOB>
      <Employee>19670823</Employee>
      <Employee>19881113</Employee>
   </DOB>
</Employees>

请注意：

  1. 使用键和使用 Muenchian 方法进行分组，以便找到属于Employee.

  2. 使用<xsl:element>带有 AVT 的name属性来生成编译时名称未知的元素。

于 2010-07-02T13:07:52.340 回答
0

如果您需要多次处理节点，您可以使用模板模式。以下会做：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="yes"/>

  <xsl:template match="Employees">
    <Employees>
      <FirstName>
        <xsl:apply-templates mode="firstname" />
      </FirstName>
      <LastName>
        <xsl:apply-templates mode="lastname" />
      </LastName>
    </Employees>
  </xsl:template>

  <xsl:template match="Employee" mode="firstname">
    <Employee>
      <xsl:value-of select="FirstName"/>
    </Employee>
  </xsl:template>

  <xsl:template match="Employee" mode="lastname">
    <Employee>
      <xsl:value-of select="LastName"/>
    </Employee>
  </xsl:template>

</xsl:stylesheet>
于 2010-07-02T09:35:10.000 回答
0

好吧，我最终解决了这个问题 - 基本上我需要一个 for-each 用于第一个 Employee 中的元素，并将 for-each 中的一个变量分配给 position() 值。

然后，在第二个嵌套的 for-each 中，我循环遍历外部 Employee 元素。

对于每个 Employee 元素，我使用变量（包含内部元素的“行”）来索引它的内部元素。

就像是：

<xsl:for-each select="*/Employee[1]/.">
    <tr>
        <xsl:variable name="row" select="position()" />
        <xsl:for-each select="/*/Employee">
            <td>
                <xsl:value-of select=".[$row]/."/>
            </td>
        </xsl:for-each>
    </tr>
</xsl:for-each>

我承认，我的更简洁一些，但这就是要点。

简而言之（深呼吸）循环遍历第一个外部元素的元素列表。对于每一个，循环遍历外部元素并使用内部元素的索引顺序选择内部元素。

于 2010-07-02T10:02:04.957 回答