4

在过去的几天里，我一直在编写一个我认为很容易但似乎并不容易的脚本，我也明白为什么。我的问题是如何解决它。

我需要解释的批处理脚本：

我有一个在 cmd.exe 中运行的脚本，它可以执行很多操作，例如将大量文件从一个位置移动到另一个位置。让我们称之为 movefile.cmd。该脚本有效，但有时会停止（很少 - 让我们不讨论为什么和那个脚本）。该脚本始终运行很重要，因此我的想法是创建一个退出 cmd.exe 的批处理，然后每隔一小时左右重新打开脚本。让我们调用这个脚本restartcmd.bat

听起来很简单，因为我可以这样做：

@echo off

:loop

start c:\script\movefile.cmd 

Timeout /nobreak /t 3600

Taskkill cmd.exe

goto loop

但显然这不起作用，因为我的新脚本也在 cmd.exe 中运行，所以它也会杀死这个进程。

我试过的：

所以我复制了一个cmd.exe，重命名为dontkillthis.exe。我运行 dontkillthis.exe，然后从 dontkillthis.exe 打开 restardcmd.bat - 这非常有效！但我需要能够只是 dobbleclick 我的脚本而不是这样做。为什么？因为它应该尽可能简单，我希望我的 restartcmd.bat 位于我的启动文件夹中。

我一直在寻找获取 cmd.exe 的确切进程 ID 并关闭它以便我的 dontkillthis.exe 保留的想法，但我似乎无法确定它。尝试了这里写的所有内容，如何杀死除当前正在运行的批处理文件之外的所有批处理文件，但我无法让它工作。

我不确定我是否感到困惑，或者这样做实际上是否有点困难。

我真的很感激这里的一些帮助。

最好的祝福

莫

4

6 回答 6

12

首先，您需要当前 CMD 实例的 PID。这个话题已经在这里讨论过了。我将为您提供我的解决方案 - getCmdPID.bat

这是脚本（getCmdPID 应该在同一目录中）：

@echo off

call getCmdPID
set "current_pid=%errorlevel%"

for /f "skip=3 tokens=2 delims= " %%a in ('tasklist /fi "imagename eq cmd.exe"') do (
    if "%%a" neq "%current_pid%" (
        TASKKILL /PID %%a /f >nul 2>nul
    )
)
于 2015-04-01T11:53:11.773 回答
1

通常使用以下命令，我应该能够找到 PID。不幸的是，这种情况并非如此。

title exclude &tasklist /NH /v /fo csv /FI "WINDOWTITLE ne exclude*" /FI "IMAGENAME eq cmd.exe" /FI "STATUS eq running"

所以为了实现我的目标，我使用了以下命令： FIND /I "exclude" 1>NUL

@echo off
TITLE exclude
(for /f "usebackq  tokens=*" %%a in (`tasklist /NH /v /fo csv /FI "IMAGENAME eq cmd.exe" /FI "STATUS eq running"`) do (
  (
    echo %%a | FIND /I "exclude" 1>NUL
  ) || ( 
    for /f "usebackq tokens=2 delims=," %%i in (`echo %%a`) do (
      echo TASKKILL /PID %%~i /f
    )
  )
)
)>_output-taskill.txt
TYPE _output-taskill.txt

在一行中杀死所有进程的另一种方法是在命令上使用过滤器taskkill，过滤器应该如下所示：

TASKKILL /F /FI "PID ne XXXX" /FI "IMAGENAME eq cmd.exe" /IM cmd.exe

eq（相等）

ne（不等于）

gt（大于）

lt（小于）

@echo off
TITLE exclude
(for /f "usebackq tokens=2 delims=," %%a in (`tasklist /NH /v /fo csv /FI "IMAGENAME eq cmd.exe" /FI "STATUS eq running" ^| FIND /I "exclude"`) do (
    echo TASKKILL /F /FI "PID ne %%~a" /FI "IMAGENAME eq cmd.exe" /IM cmd.exe
  )
)>_output-taskill.txt
TYPE _output-taskill.txt
于 2015-09-13T18:15:16.887 回答
1

我找到了一个解决方案，它利用文本文件来跟踪 bat 文件具有的所有以前的 PID。它会尝试以静默方式杀死它们，然后将当前 PID 添加到列表中。

如果您不希望它杀死旧的、已经存在的进程，只需将具有“taskkill”的行替换为您想要对其执行的任何操作。

（可能需要您以管理员身份运行才能获得杀死重复进程的权限。如果您不想每次都以管理员身份运行，请参阅下面的权限提升代码以获取可选实现。）

@echo off
set WorkingDir=%cd% 
if exist MostRecentPID.txt ( del "PIDinfo.txt"  /f /q ) > nul
cd ..\..\..\..\..\..\..
title mycmd
tasklist /v /fo csv | findstr /i "mycmd" > %WorkingDir%\PIDinfo.txt
set /p PIDinfo=<%WorkingDir%\PIDinfo.txt

REM below, the 11 means get substring starting a position 11 with length of 5 characters. The tasklist command gives a long and verbose value so this will get just the PID part of the string.
set PID5chars=%PIDinfo:~11,5%
set PID4chars=%PIDinfo:~11,4%

if exist PreviousPIDs.txt (
    for /F "tokens=*" %%A in (PreviousPIDs.txt) do taskkill.exe /F /T /PID %%A > nul 2>&1
    goto CheckIfFourCharPID
)

:CheckIfFourCharPID
if %PID4chars% gtr 8100 (
    for /F "tokens=*" %%A in (PreviousPIDs.txt) do taskkill.exe /F /T /PID %%A > nul 2>&1
    echo %PID4chars% >> "PreviousPIDs.txt"
) else (
    echo %PID5chars% >> "PreviousPIDs.txt"
)

解释：（警告：非常技术性）

-此解决方案获取 tasklist 命令的子字符串以仅获取 PID。cmd.exe 的 PID 不会大于 18100，因此请检查 PID4chars 是否大于 8100，以便我们知道它是 4 位数字还是 5 位数字

案例1：像17504这样的5位PID有一个PID5chars val 17504和一个PID4chars val 1750，所以我们将PID5chars添加到PIDs的文本文件中以杀死

案例 2：像 8205 这样的 4 位 PID 的 PID5chars val 为 8205" 和 PID4chars val 为 8205，所以我们将 PID4chars 添加到 PIDs 的文本文件中以杀死

案例3：像4352这样的4位PID，PID5chars val为4352"，PID4chars val为4352，所以我们将PID4chars添加到PIDs的文本文件中以杀死

可选的许可海拔代码

（把它放在你的 bat 文件的顶部，它会以管理员身份自动运行它。）

    @echo off
    setlocal DisableDelayedExpansion

    set "batchPath=%~0"
    for %%k in (%0) do set batchName=%%~nk
    cd ..\..\..\..\..\..\..\..
    if exist %cd%\Temp (
    set temp=%cd%\Temp
    goto vbsGetPrivileges
    )
    if exist %cd%\Windows\Temp (
    set temp=%cd%\Windows\Temp
    goto vbsGetPrivileges
    )
    set temp=%cd%

    :vbsGetPrivileges
    set "vbsGetPrivileges=%temp%\OEgetPriv_%batchName%.vbs"
    setlocal EnableDelayedExpansion

    :CheckIfRunningAsAdmin
    net session >nul 2>&1
    if %ERRORLEVEL% == 0 ( 
        goto gotPrivileges 
    ) else ( goto ElevatePermissions )

    :ElevatePermissions
    if '%1'=='ELEV' (echo ELEV & shift /1 & goto gotPrivileges)
    ECHO Set UAC = CreateObject^("Shell.Application"^) > "%vbsGetPrivileges%"
    ECHO args = "ELEV " >> "%vbsGetPrivileges%"
    ECHO For Each strArg in WScript.Arguments >> "%vbsGetPrivileges%"
    ECHO args = args ^& strArg ^& " "  >> "%vbsGetPrivileges%"
    ECHO Next >> "%vbsGetPrivileges%"
    ECHO UAC.ShellExecute "!batchPath!", args, "", "runas", 1 >> "%vbsGetPrivileges%"
    "%SystemRoot%\System32\WScript.exe" "%vbsGetPrivileges%" %*
    exit /B

    :gotPrivileges
    setlocal & pushd .
    cd /d %~dp0
    if '%1'=='ELEV' (del "%vbsGetPrivileges%" 1>nul 2>nul  &  shift /1)
    net session >nul 2>&1
    if %ERRORLEVEL% == 0 (
        goto Continue
    ) else (
        REM unable to elevate permissions so tell user to run file as admin manually
        echo Please re-run this file as administrator. Press any key to exit...
        pause > nul
        goto Exit
     )

    :Continue
    <insert rest of code here>
于 2019-08-16T17:38:03.297 回答
0

获得你的 PID 会好得多movefile.cmd。如果你可以编辑它，添加一个title MyMoveFileProcess并获取它的PID

for /f "tokens=2" %%i in ('tasklist /v ^|find "MyMoveFileProcess"') do set PID=%%i

然后你可以用taskkill /pid %pid%

除了改变你的movefile.cmd，你也可以用一个标题开始它：

start "MyMoveFileProcess" c:\script\movefile.cmd
于 2015-04-01T11:08:37.417 回答
0

另外，仅供参考。我发现可以根据标题停止和启动其他 cmd 文件，这将是我问题解决方案的替代方案。所以让我们说movefile.cmd在它的脚本中有这一行：（Title "movefile"“”很重要）。然后我可以写taskkill /F /FI "WindowTitle eq Administrator: \"movefile"" /T在restartcmd.bat:)

于 2015-04-14T07:30:13.603 回答
-2

几行将帮助您实现这一目标：

TITLE exclude
taskkill /IM cmd.exe /FI "WINDOWTITLE ne exclude*"
于 2016-06-09T14:21:38.500 回答