1

我的代码引发了我无法理解的异常。我还是编程新手，所以请耐心等待。这是我的代码：

<cfsetting showdebugoutput="false">
<cfprocessingdirective pageencoding="utf-8">
<html>
    <head>
        <title>Test</title>
    </head>
<body>

    <cfset key = generateSecretKey("AES")>

    <cfscript>
        if (isDefined("form")) {
            encFieldnamesArr = listToArray(form.fieldnames);
            decFieldnamesArr = arrayNew(1);

            for (paramName in encFieldnamesArr) {
                arrayAppend(decFieldnamesArr, "#decrypt(paramName, key, 'AES', 'HEX')#");
            }
        }
    </cfscript>

    <cfform>
        <cfinput name="#encrypt("firstName", key, "AES", "HEX")#" type="text" />
        <cfinput name="#encrypt("lastName", key, "AES", "HEX")#" type="text" />
        <cfinput type="submit" name="#encrypt("action", key, "AES", "HEX")#" value="submit" />
    </cfform>

</body>
</html>

它抛出这个异常：

 An error occurred while trying to encrypt or decrypt your input string: Invalid padding..

The error occurred in C:/ColdFusion11/cfusion/wwwroot/test/index.cfm: line 17

15 : 
16 :            for (paramName in encFieldnamesArr) {
17 :                arrayAppend(decFieldnamesArr, "#decrypt(paramName, key, 'AES', 'HEX')#");
18 :            }
19 :        }

“无效填充”是什么意思？谢谢

4

1 回答 1

1

key解密时，您必须使用与加密值完全相同的方法。每次页面加载时，您的代码都会生成一个全新的密钥：

<cfset key = generateSecretKey("AES")>

所以代码是使用一个密钥来加密的。然后在提交表单时，它使用一个完全不同的键来decrypt(). 因此错误。

例子：

<cfscript>
  // WORKS: encrypt and decrypt with the same key
  key = generateSecretKey("AES");
  text = "the quick brown fox jumps over the lazy dog";
  encrypted = encrypt(text, key, 'AES', 'HEX');
  decrypted = decrypt(encrypted, key, 'AES', 'HEX');
  writeOutput("<br>text="& text);
  writeOutput("<br>key="& key);
  writeOutput("<br>encrypted="& encrypted);
  writeOutput("<br>decrypted="& decrypted);

  // FAILS: Decrypting with a *different* key will fail
  key = generateSecretKey("AES");
  writeOutput("<br>key="& key);
  decrypted = decrypt(encrypted, key, 'AES', 'HEX');
</cfscript>

我意识到以上只是一个实验，但有一些提示：

  1. FORM是一个系统结构，所以它应该总是被定义。通常，您会检查是否存在特定的表单字段名称。IE

    structKeyExists(FORM, "someFieldName")

  2. 由于您没有使用 cfform/cfinput 的任何额外功能（无论如何都不是很好），因此只需使用普通的 html<form>和<input>标签。使用 CF 版本会导致 CF 向您的页面添加大量不必要的 javascript 代码。

  3. 解密周围不需要双引号或#符号。只需使用：

    decrypt(paramName, key, 'AES', 'HEX')

于 2014-12-17T02:58:33.210 回答