1

我正在尝试使用 VBA 让我的生活更轻松，但我一直遇到无法解决的问题。基本上我想要的是将我拥有的几个输出 csv 文件中的一些值复制到一个格式良好的 excel 文件中。然后根据一些基数删除值或格式化单元格。
但是，我不断收到相同的错误消息运行时错误“1004”应用程序定义或对象定义错误。我正在使用许多输出文件并将值粘贴到同一个表文件但在不同的工作表（10.2a、10.2b、10.2c、...）上，方法是为每个工作表设置宏。我使用另一个宏运行所有宏，该宏包含我在其他帖子中看过很多但不明白错误来自哪里的所有其他宏。任何帮助将非常感激。下面以我用于一张纸的代码为例。

Sub Table_10_2a()
        '
        ' Copy Data from one file to another
        '
        Dim Output As Workbook
        Dim Table As Workbook
        Dim i As Integer

        'Open workbooks
        Set Output = Workbooks.Open("O:\...\Output.csv")
        Set Table = Workbooks.Open("O:\...\Table.xlsx") 

        'Copy paste data from output file to Table
        Output.Sheets("Output1").Range("B3:E7").Copy
        Table.Sheets("10.2a").Range("B11").PasteSpecial xlValues

        Output.Sheets("Output1").Range("B9:E13").Copy
        Table.Sheets("10.2a").Range("B17").PasteSpecial xlValues

        Output.Sheets("Output1").Range("B15:E15").Copy
        Table.Sheets("10.2a").Range("B23").PasteSpecial xlValues

        Output.Sheets("Output1").Range("B17:E21").Copy
        Table.Sheets("10.2a").Range("B26").PasteSpecial xlValues

        Output.Sheets("Output1").Range("B23:E27").Copy
        Table.Sheets("10.2a").Range("B32").PasteSpecial xlValues

        Output.Sheets("Output1").Range("B29:E29").Copy
        Table.Sheets("10.2a").Range("B38").PasteSpecial xlValues

        Output.Sheets("Output1").Range("B30:E30").Copy
        Table.Sheets("10.2a").Range("B40").PasteSpecial xlValues

        For i = 2 To 5
        'Delete cells for values below 30
         If Table.Sheets("10.2a").Cells(40, i).Value < 30 Then
            Table.Sheets("10.2a").Range(Cells(26, i), Cells(36, i)).ClearContents
            Table.Sheets("10.2a").Cells(38, i).NumberFormat = """[""0""]"""
            Table.Sheets("10.2a").Cells(40, i).NumberFormat = """[""0""]"""
         End If

    'Format cells for values below 50
        If Table.Sheets("10.2a").Cells(40, i).Value < 50 And Table.Sheets("10.2a").Cells(40, i).Value > 30 Then
            Table.Sheets("10.2a").Range(Cells(26, i), Cells(38, i)).NumberFormat = """[""0.0""]"""
            Table.Sheets("10.2a").Cells(40, i).NumberFormat = """[""0""]"""
        End If

        Next i

        'Save file
            Table.Save

        'Close files
            Output.Close
            Table.Close

        End Sub
4

1 回答 1

1

这种使用CellsinsideRange来构建单元块通常会成为不合格引用的牺牲品。在这种情况下，您正在使用Table.Sheets("10.2a")为 指定工作表，Range但没有在 上使用相同的限定符Cells。这意味着Cells它将使用可用的默认上下文，该上下文随代码执行的位置而异。可能性：

  • 在代码模块内部或ThisWorkbook,Cells指的是ActiveSheet
  • 后面的 Worksheet 代码里面，Cells指的是Worksheet不管ActiveSheet

用于Address绕过不同的工作表

一种方法是遵循对Cellswith的调用Address。这解决了问题，因为Address返回没有工作表名称的单元格地址。然后Range在其上下文中解释这是Sheets("10.2a").

Range(Cells(26, i).Address, Cells(36, i).Address).ClearContents

合格的参考（通常首选）

Cells解决此错误的另一种方法是通过在:之前添加工作表名称来限定引用Table.Sheets("10.2a").Cells。全线：

Range(Table.Sheets("10.2a").Cells(26, i), Table.Sheets("10.2a").Cells(36, i)).ClearContents

With... End With这种类型的代码在一个块中看起来更好。

于 2014-07-22T12:30:28.787 回答