1

我的问题是我想在 PL/SQL 中执行动态 SQL 查询，其中我有一个 ID 列表作为我的数组绑定。在 Oracle 文档中，我找到了一些如何将数字列表连接到 DML 语句的示例。( http://docs.oracle.com/cd/B28359_01/appdev.111/b28419/d_sql.htm#i996963 )

现在我正在尝试为 Select-Statements 做同样的事情。我知道我可以将 Array-Binds 用于execute immediate-Statement. 但这有一个缺点，即在执行语句之前我必须知道绑定变量的确切数量。这就是我必须使用 dbms_sql 的原因。

以下示例仅返回 1 行，但应返回 3 行。有谁知道我的示例的问题是什么？

--TestData:
CREATE TABLE PERSON AS
SELECT LEVEL AS ID, 'Person_'||LEVEL AS NAME
FROM DUAL CONNECT BY LEVEL <= 5;

declare
    p_ids dbms_sql.number_table;
    c number; 
    dummy NUMBER;
    p_name varchar2(100);
begin
    p_ids(1) := 2;
    p_ids(2) := 3;
    p_ids(3) := 4;
    --
    c := DBMS_SQL.OPEN_CURSOR;
    DBMS_SQL.PARSE(c, 'select name from PERSON where id in(:num_array)', DBMS_SQL.NATIVE);   
    dbms_sql.define_column(c, 1, p_name, 100); 
    DBMS_SQL.BIND_ARRAY(c, ':num_array', p_ids);    
    dummy := DBMS_SQL.EXECUTE(c);
    --
    loop
        exit when dbms_sql.fetch_rows(c) <=0;
        dbms_sql.column_value(c, 1, p_name);
        dbms_output.put_line(p_name);
    end loop;
    DBMS_SQL.CLOSE_CURSOR(c);
end;
4

1 回答 1

0

这是我当前将多个值绑定到 Select 语句的解决方案，也许有人需要它：

--TestData:
CREATE TABLE PERSON AS
SELECT LEVEL AS ID, 'Person_'||LEVEL AS NAME
FROM DUAL CONNECT BY LEVEL <= 5;

declare
    c number; 
    dummy NUMBER;
    p_name varchar2(100);
    xml$ varchar2(1000);
begin
    --Generate a XML-List instead of dbms_sql.number_table:
    xml$ := '<ids><id>2</id><id>3</id><id>4</id></ids>';
    --
    c := dbms_sql.open_cursor;
    --Using XML-Functions for extracting the Values from the XML-String
    DBMS_SQL.PARSE(c, 'select name 
                         from PERSON 
                        where id in(select extractvalue(value(x), ''id'')
                                      from table(xmlsequence(xmltype(:ids).extract(''ids/*'')))x)'
                       , DBMS_SQL.NATIVE);   
    dbms_sql.define_column(c, 1, p_name, 100); 
    DBMS_SQL.BIND_variable(c, ':ids', xml$);    
    dummy := DBMS_SQL.EXECUTE(c);
    --
    loop
        exit when dbms_sql.fetch_rows(c) <=0;
        dbms_sql.column_value(c, 1, p_name);
        dbms_output.put_line(p_name);
    end loop;
    DBMS_SQL.CLOSE_CURSOR(c);
end;
于 2014-07-09T08:52:59.380 回答