0

temp_file.txt

|112233456543214 |
|154233456873221|
|154233456868320|

当我使用下面的 nawk 命令时，如果您有空白空间，我看到数据正在跳过，所以我必须修剪空白。我必须在下面的命令中包含空白修剪（知道单独使用 nwak 命令）是挑战。我的问题是如何在以下命令中包含空格修剪

nawk -F '|' 'BEGIN{FS=OFS="|"}(length($2) >=13){
  $2=substr($2,1,6)"xxxxxx"substr($2,length($2)-3)}1' temp_file.txt>tmp.txt && mv tmp.txt temp_file.txt
4

2 回答 2

3

因为第一个 char 是一个管道，所以您$1将始终是一个空字符串。您想检查$2您的数据。

awk -F\| -v OFS=\| '{gsub(/(^[[:blank:]]+)|([[:blank:]]+$)/, "", $2)} 1' <<END
|112233456543214 |
|  154233456873221  |
| 154233456868320|
END

|112233456543214|
|154233456873221|
|154233456868320|

如果你使用-F，你也不需要在 BEGIN 块中定义 FS 。

如果你想把它拼出来：

$ nawk -F '|' '
    BEGIN {OFS = FS}
    function obfuscate(string) {
        gsub(/(^[[:blank:]]+)|([[:blank:]]+$)/, "", string)
        return substr(string,1,6) "xxxxxx" substr(string,length(string)-3)
    }
    length($2) >= 13 {$2 = obfuscate($2) }
    1
' <<END
|112233456543214 |
|  154233456873221  |
|123456789012|
|1234567890123|
|12345678901234|
| 154233456868320|
END

|112233xxxxxx3214|
|154233xxxxxx3221|
|123456789012|
|123456xxxxxx0123|
|123456xxxxxx1234|
|154233xxxxxx8320|
于 2014-05-12T15:23:36.033 回答
0

nawk支持定义中的正则表达式FS。您可以使用它来修剪前导和尾随空格或制表符。

nawk -F '[[:blank:]]*[|][[:blank:]]*' 'BEGIN{OFS = "|"} (length($2) >= 13) {
    $2 = substr($2, 1, 6) "xxxxxx" substr($2, length($2) - 3)}1'

管道被方括号包围，以防止它充当正则表达式交替运算符。正则表达式表示使用零个或多个空格（空格或制表符）的组合，后跟一个管道字符，然后是零个或多个空格作为字段分隔符。

于 2014-05-12T16:31:55.470 回答