0

我正在尝试编写一个批处理文件，该文件将从目录中提取文件并通过电子邮件发送。这很容易，我遇到的问题是需要通过电子邮件发送的文件的数量或时间/日期戳越来越多。显然，由于时间日期问题的不一致，我可以将文件名更改为增加的数字。我的问题是如何指定目录中最新的文件或文件名中编号最大的文件。我已经搜索了一段时间，但没有找到任何有帮助的东西。

@echo off
setlocal

set Port=465
set SSL=True
set From="email@blah.com"
set To="email@blah.com"
set Subject="Subject"
set Body="Body"
set SMTPServer="smtp.gmail.com"
set User="username"
set Pass="password"
set fileattach="\\networklocation\filename.jpg"

if "%~7" NEQ "" (
set From="%~1"
set To="%~2"
set Subject="%~3"
set Body="%~4"
set SMTPServer="%~5"
set User="%~6"
set Pass="%~7"
set fileattach="%~8"
)

set "vbsfile=%temp%\email-bat.vbs"
del "%vbsfile%" 2>nul
set cdoSchema=http://schemas.microsoft.com/cdo/configuration
echo >>"%vbsfile%" Set objArgs       = WScript.Arguments
echo >>"%vbsfile%" Set objEmail      = CreateObject("CDO.Message")
echo >>"%vbsfile%" objEmail.From     = %From%
echo >>"%vbsfile%" objEmail.To       = %To%
echo >>"%vbsfile%" objEmail.Subject  = %Subject%
echo >>"%vbsfile%" objEmail.Textbody = %body%
if exist %fileattach% echo >>"%vbsfile%" objEmail.AddAttachment %fileattach%
echo >>"%vbsfile%" with objEmail.Configuration.Fields
echo >>"%vbsfile%"  .Item ("%cdoSchema%/sendusing")        = 2 ' not local, smtp
echo >>"%vbsfile%"  .Item ("%cdoSchema%/smtpserver")       = %SMTPServer%
echo >>"%vbsfile%"  .Item ("%cdoSchema%/smtpserverport")   = %port%
echo >>"%vbsfile%"  .Item ("%cdoSchema%/smtpauthenticate") = 1 ' cdobasic
echo >>"%vbsfile%"  .Item ("%cdoSchema%/sendusername")     = %user%
echo >>"%vbsfile%"  .Item ("%cdoSchema%/sendpassword")     = %pass%
echo >>"%vbsfile%"  .Item ("%cdoSchema%/smtpusessl")       = %SSL%
echo >>"%vbsfile%"  .Item ("%cdoSchema%/smtpconnectiontimeout") = 30
echo >>"%vbsfile%"  .Update
echo >>"%vbsfile%" end with
echo >>"%vbsfile%" objEmail.Send

cscript.exe /nologo "%vbsfile%"

echo email sent (if variables were correct)

多年来，这个网站帮助了我很多，我只想对社区说声谢谢。

4

2 回答 2

0

这是我为此编写的一个函数。它类似于 David 的代码，但使用 /od 获取找到的第一个文件然后退出循环。如果目录中有很多文件，这将加快速度。它还可以让您轻松指定是否要最新创建、访问或写入。

Call :getlatestfile "C:\files" "w" latest
echo %latest%
exit /b         


:getlatestfile <path> <c/a/w> <return>
setlocal
for /f %%b in ('dir "%~1" /b /o-d /t%~2') do (
set "latest=%%b" & goto :out)
:out
endlocal & set "%~3=%latest%"
于 2014-03-18T18:26:34.113 回答
0

使用下面的行代替set fileattach="\\networklocation\filename.jpg"

for /f "delims=" %%a in ('dir "\\networklocation\*.jpg" /b /od') do set fileattach="\\networklocation\%%a"

它选择最新的文件（如果文件夹中有数千个 .jpg 文件，那么预计会有短暂的延迟，或者要求方法 B :)）

换\\networklocation两个地方。

于 2014-03-19T04:34:21.563 回答