asp-classic - 在数组中添加值 - 经典 ASP

Question

我正在使用以下内容For loop显示文件夹中的所有文件，不包括带有.asp扩展名的文件。

我想将文件名添加到数组中，以便将其objFileItem.Name添加到tmpArray.

我尝试使用tmpArray(k) = objFileItem.Name但它抛出一个错误。

For Each objFileItem In objFolderContents
    strFileExtension = LCase(Mid(objFileItem.Name, _
        InStrRev(objFileItem.Name, ".", -1, 1) + 1))
        If strFileExtension <> "asp"  Then
            strImages=strImages & objFileItem.Name
        end if

Next

Answer 1

如果您有合理数量的项目（少于 100 个），只需使用如下动态数组：

Dim tmpArray()
ReDim tmpArray(-1)
For Each objFileItem In objFolderContents
    strFileExtension = LCase(Mid(objFileItem.Name, _
        InStrRev(objFileItem.Name, ".", -1, 1) + 1))
    If strFileExtension <> "asp"  Then
        strImages = strImages & objFileItem.Name
        ReDim Preserve tmpArray(UBound(tmpArray) + 1)
        tmpArray(UBound(tmpArray)) = objFileItem.Name
    End If
Next

'show array items:
Response.Write("Total of " & (UBound(tmpArray) + 1) & " files:<br />")
For k=0 To UBound(tmpArray)
    Response.Write(tmpArray(k) & "<br />")
Next

'when done with the array, release resources to prevent memory leak:
Erase tmpArray