8

我是线程新手，所以我已经尝试了几个小时（我正在使用 XE4），

我有一个简单的线程

type
  TSendThread = class(TThread)
  private
  public
    procedure proc(const s : string);
  protected
    procedure Execute; override;
  end;

  procedure TSendThread.proc(const S: String);
  begin
    showmessage(s);
  end;

现在，在我的主要形式中，我想用以下方式调用“proc”：

procedure TForm1.Button1Click(Sender: TObject);
var
  t : TSendThread;
begin
    t := TSendThread.create(true);
    t.Synchronize(nil, t.proc('foo'));
end;

但是每当我尝试编译时，我都会得到：

没有可以使用这些参数调用的“同步”的重载版本

这没有意义（对我来说），因为当我从“proc”中删除“S”参数时它工作正常。

4

3 回答 3

19

查看 的各种声明TThread.Synchronize()。您正在尝试调用以 aTThreadMethod作为输入的版本。 TThreadMethod是无参数的：

TThreadMethod = procedure of object;

这就是为什么传球t.Proc有效但传球t.Proc('foo')无效的原因。

话虽如此，您完全在滥用TThread.Synchronize(). 您无需创建TThread对象即可使用Synchronize(). 如果你确实创建了一个TThread对象，让它真正做一些事情，就像这样：

type
  TSendThread = class(TThread)
  public
    fStr: String;
    procedure DoProc;
    procedure Proc(const S: string);
  protected
    procedure Execute; override;
  end;

  procedure TSendThread.Execute;
  begin
    Proc('foo');
  end;

  procedure TSendThread.Proc(const S: string);
  begin
    fStr := S;
    Synchronize(DoProc);
  end;

  procedure TSendThread.DoProc;
  begin
    ShowMessage(fStr);
  end;

procedure TForm1.Button1Click(Sender: TObject);
var
  t : TSendThread;
begin
  t := TSendThread.Create(False);
  t.WaitFor;
  t.Free;
end;

但是，因为您使用的是 XE4，所以Synchronize()也支持匿名过程，这将TSendThread在此示例中完全消除您的类，例如：

procedure TForm1.Button1Click(Sender: TObject);
begin
  TThread.Synchronize(nil,
    procedure
    begin
      ShowMessage('foo');
    end
  );
end;

更新：给出关于你真正想用你的线程做什么的新信息，你需要像这样去做：

type
  TSendThread = class(TThread)
  private
    fURL, fMethod, fParam: string;
  protected
    procedure Execute; override;
  public
    constructor Create(aURL, aMethod, aParam: string);
  end;

constructor TSendThread.Create(aURL, aMethod, aParam: string);
begin
  inherited Create(False);
  fURL := aUrl;
  fMethod := aMethod;
  fParam := aParam;
end;

procedure TSendThread.Execute;
begin
  // use fURL, fMethod, and fParam as needed...
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  t : TSendThread;
begin
  t := TSendThread.Create('url', 'method', 'param');
  ...
end;

或者像这样：

type
  TSendThread = class(TThread)
  private
    fURL, fMethod, fParam: string;
    procedure GetValues;
  protected
    procedure Execute; override;
  end;

procedure TSendThread.GetValues;
begin
  fURL := ...;
  fMethod := ...;
  fParam := ...;
end;

procedure TSendThread.Execute;
begin
  Synchronize(GetValues);
  // use fURL, fMethod, and fParam as needed...
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  t : TSendThread;
begin
  t := TSendThread.Create(False);
  ...
end;
于 2013-06-01T08:08:20.843 回答
3

Synchronize 只需要一个无参数的过程，我相信你已经知道了。这意味着您必须使用从主线程获得的属性才能用它做某些事情。例如，我的线程对象被命名为监视器：

Synchronize(UpdateCaption);  // as called in the thread code.

procedure monitor.UpdateCaption;
// synchronize procedure for monitor thread - updates memo on form.
begin
  With Form1.CommandText.Lines do
    Add(TextString);
end;

或者，您将消息传递给主线程，但这是一种快速的方法。

于 2013-06-01T07:59:30.887 回答
0

另一种方法是编写一个不带参数的包装函数，并在Synchronize().

于 2017-05-04T08:31:45.810 回答