6

我在调用 BUILDARGS 时无法正确使用 MooseX::Declare。

我正在尝试创建一个对象作为文件的接口。（具体来说，我想要一个二进制文件的接口，让我可以查看文件中接下来的几个字节，然后将它们切掉以进行进一步处理。）

我希望能够像这样创建这些对象之一

my $f = binary_file_buffer->new( $file_name );

然后像这样使用它

while( my $block_id = $f->peek( $id_offset, $id_length ) ) {
    $block_id = unpack_block_id( $block_id );
    $munge_block{ $block_id }->(
        $f->pop( $block_size[ $block_id ] )
    );
}

我的 binary_file_buffer 类定义/声明看起来像这样

use MooseX::Declare;
class binary_file_buffer {
    use FileHandle;
    use Carp;

    has _file      => ( is => 'ro', isa => 'FileHandle' );
    has _file_name => ( is => 'ro', isa => 'Str' );
    has _buff      => ( is => 'rw', isa => 'Str',  default => '' );

    method BUILDARGS ( Str $file_name ) {
      my $file = FileHandle->new( $file_name );
      carp "unable to open $file_name : $!" unless defined $file;
      $file->binmode;
      return (
        _file_name => $file_name,
        _file      => $file,
      );
    }

    # get the next n bytes from the buffer.
    method pop ( Int $len ) {
        # ... Make sure there is data in _buff
        return substr( $self->{_buff}, 0, $len, '' );
    }

    # Look around inside the buffer without changing the location for pop
    method peek ( Int $offset, Int $len ) {
        # ... Make sure there is data in _buff
        return substr( $self->{_buff}, $offset, $len );
    }
}

（这里没有包含缓冲区加载和管理代码。这很简单。）

method问题是，我在BUILDARGS声明中使用了关键字。因此，MooseX::Declare 需要一个binary_file_buffer 对象作为BUILDARGS. 但是BUILDARGS获取传递给 new 的参数，所以第一个参数是字符串a 'binary_file_buffer'，即包的名称。结果，它无法通过类型检查并在使用 new 创建对象时死掉，就像我在第一个代码片段中所做的那样。（至少这是我对正在发生的事情的理解。）

我得到的错误信息是：

Validation failed for 'MooseX::Types::Structured::Tuple[MooseX::Types::Structured::Tuple[Object,Str,Bool],MooseX::Types::Structured::Dict[]]' failed with value [ [ "binary_file_buffer", "drap_iono_t1.log", 0 ], {  } ], Internal Validation Error is: Validation failed for 'MooseX::Types::Structured::Tuple[Object,Str,Bool]' failed with value [ "binary_file_buffer", "drap_iono_t1.log", 0 ] at C:/bin/perl/site/lib/MooseX/Method/Signatures/Meta/Method.pm line 445
 MooseX::Method::Signatures::Meta::Method::validate('MooseX::Method::Signatures::Meta::Method=HASH(0x2a623b4)', 'ARRAY(0x2a62764)') called at C:/bin/perl/site/lib/MooseX/Method/Signatures/Meta/Method.pm line 145
 binary_file_buffer::BUILDARGS('binary_file_buffer', 'drap_iono_t1.log') called at generated method (unknown origin) line 5
 binary_file_buffer::new('binary_file_buffer', 'drap_iono_t1.log') called at logshred.pl line 13

我喜欢关键字为 $file_name 提供的类型检查糖method，但我不知道如何获取它，因为从BUILDARGS技术上讲这不是一种方法。

MooseX::Declare 有没有办法跳过$self创建，或者类似的东西？

我这样做是正确的 MooseX::Declare 方式吗？还是我错过了什么？

4

3 回答 3

10

我认为您想要类似的东西method BUILDARGS (ClassName $class: Str $filename) { ... }，其中您将调用者明确定义为ClassName $class.

于 2009-09-03T04:09:18.187 回答
2

我想你想要：

#!/use/bin/perl

use strict;
use warnings;

use MooseX::Declare;
class BinaryFile::Buffer {
    use FileHandle;
    use Carp;

    has file      => ( is => 'ro', isa => 'FileHandle');
    has file_name => ( is => 'ro', isa => 'Str');
    has _buff     => (
        is       => 'rw',
        isa      => 'Str',
        default  => '',
        init_arg => undef
    );

    sub BUILDARGS {
        my ($class, $file_name) = @_;
        my $file = FileHandle->new( $file_name ) or do {
            carp "unable to open ", $file_name, " : $!";
            return;
        };
        $file->binmode;
        return $class->SUPER::BUILDARGS(
                file_name => $file_name,
                file      => $file
        );
    }

    # get the next n bytes from the buffer.
    method pop(Int $len) {
        # ... Make sure there is data in _buff
        return substr( $self->buff, 0, $len, '' );
    }

    # Look around inside the buffer without changing the location for pop
    method peek(Int $offset, Int $len) {
        # ... Make sure there is data in _buff
        return substr( $self->buff, $offset, $len );
    }
}

my $f = BinaryFile::Buffer->new($0);

print $f->file_name, "\n";
于 2009-09-03T04:22:18.597 回答
1

也是一种非常巧妙的方法（只是我面前答案的扩展）：

use MooseX::MultiMethods;

multi method BUILDARGS (ClassName $class: Str $filename) {

#do whatever you want to do if only a strg is passed

}

这样，MooseX::MultiMethods 会注意，如果您不调用 FileHandle->new( $file_name )，

但

FileHandle->new(
_filename => $file_name
);

（这是正常的语法），

它仍然可以工作！

此外，您可以（这对文件名不太有用，但在其他情况下）

添加一个

multi method ( ClassName $class, Int $some_number ){}

这样，new 现在可以处理 hashrefs、整数和字符串......

哦，可能性... ;)

于 2009-11-02T01:02:08.620 回答