perl - 如何使用 Perl 在我的字符串中提取 = 之后的值？

Question

我有一个这样的字符串

field1=1 field2=2 field3=abc

我想将其输出为

2,1,abc

关于如何解决这个问题的任何想法？我可以编写一个小的 C 或 Java 程序来执行此操作，我试图找出一种在 Perl 中执行此操作的简单方法。

Answer 1

use strict;
use warnings;

my $string = 'field1=1 field2=2 field3=abc';
my @values = ($string =~ m/=(\S+)/g);
print join(',', @values), "\n";

Answer 2

#!/usr/bin/perl

use strict;
use warnings;

# Input string
my $string = "field1=1 field2=2 field3=abc";
# Split string into a list of "key=value" strings
my @pairs = split(/\s+/,$string);
# Convert pair strings into hash
my %hash = map { split(/=/, $_, 2) } @pairs;
# Output hash
printf "%s,%s,%s\n", $hash{field2}, $hash{field1}, $hash{field3};   # => 2,1,abc
# Output hash, alternate method
print join(",", @hash{qw(field2 field1 field3)}), "\n";

Answer 3

m//g在列表上下文中使用：

#!/usr/bin/perl

use strict;
use warnings;

my $x = "field1=1 field2=2 field3=abc";

if ( my @matches = $x =~ /(?:field[1-3]=(\S+))/g ) {
    print join(',', @matches), "\n";
}

__END__

输出：

C:\Temp> klm
1,2,abc

Answer 4

 $_='field1=1 field2=2 field3=abc';
 $,=',';
 say /=(\S+)/g

让我们玩 Perl 高尔夫吧：D

Answer 5

有几种方法可以做到这一点：

• 正则表达式匹配

my $s = "field1=1 field2=2 field3=abc";
$s =~ /field1=(\w*) field2=(\w*) field3=(\w*)$/; //pick out each field
print $1,$2,$3;'

12abc

• 在匹配时拆分字符串

my $s = "field1=1 field2=2 field3=abc"; 
my @arr = split / /, $s; print @arr,"\n"; //make an array of name=value pairs
my @vals = map { @pairs = split /=/, $_; $pairs[1] } @arr;  //get the values only from each pair
print @vals'

field1=1field2=2field3=abc
12abc

• 拆分并放入哈希（我认为这是最有用的）

my $s = "field1=1 field2=2 field3=abc"; 
my @arr = split / /, $s;  
my %pairs = map { split=/, $_; } @arr; 
print $pairs{field1}, $pairs{field2}, $pairs{field3}

12abc

Answer 6

my $str = 'field1=1 field2=2 field3=abc';
print(join(',', map { (split('=', $_))[1] } split(' ', $str)));

Answer 7

假设您的订购是一个错字：

#!/usr/bin/perl
use strict; use warnings;

my $str='a=1 b=2 c=abc';
my @v;
while ($str =~ /=(\S+)/g) {
    push @v, $1;
}
print join (',', @v);

Answer 8

Perl 绝对是解决这个问题的正确工具。

#! /usr/bin/perl

$str = "field1=1 field2=2 field3=abc";
$str =~ /field1=(\S+)\ field2=(\S+)\ field3=(\S+)/;
print "$1,$2,$3", "\n";

Answer 9

my $a = "field1=1 field2=2 field3=abc";
my @f = split /\s*\w+=/, $a;
shift(@f);
print join(",", @f), "\n";

Answer 10

$string="field1=1 field2=2 field3=abc";
@s=split /\s+/,$string;
$temp=$s[1];$s[1]=$s[0];$s[0]=$temp;
foreach (@s){s/.*=//; push(@a,$_ );}
print join(",",@a);

Answer 11

如果您确实需要键和值。我会将它们放入哈希中。您可以捕获“”的两侧=，然后直接放入哈希中。

use strict;
use warnings;

my $str = 'field1=1 field2=2 field3=abc';

my %fields = $str =~ / (\S+) \s* = \s* (\S+) /xg;

use YAML;
print Dump \%fields

---
字段1：1
字段2：2
字段3：ABC

欲了解更多信息，请阅读perldoc perlre。

如果您只是初学者，您可能想阅读perldoc perlretut.