2

该程序使用 AnyEvent 事件循环。程序应该读取有时（很少）出现在本地文件系统的文本文件中的新行。据我了解， AnyEvent::io 不能使用。我有什么建议从文件中读取新行？

4

1 回答 1

3

一种方法是使用跟踪和报告文件系统对象事件的工具来“监视”文件。

使用Linux::Inotify2的示例，基于模块文档中的概要

use warnings;
use strict;
use feature 'say';

use AnyEvent;
use Linux::Inotify2;

my $file = shift @ARGV || 'growing.txt';
die "Usage: $0 file-to-watch\n" if not $file;

say '';
open my $fh, '<', $file  or die "Can't open $file: $!";
print while <$fh>;

my $inotify = Linux::Inotify2->new or die "Can't create inotify object: $!";

$inotify->watch( $file, IN_MODIFY, sub {
    my $e = shift;
    if ($e->IN_MODIFY) {
        print while <$fh>;
    }
});

my $inotify_w = AnyEvent->io (
    fh => $inotify->fileno, poll => 'r', cb => sub { $inotify->poll }
);

1 while $inotify->poll;

监视器可以与许多主要的事件处理工具一起使用。此示例使用AnyEvent。

首先创建文件growing.txt，大概有一些内容。watcher.pl &然后启动程序并在打印其行时将其置于后台 ( )。然后添加到文件中

echo "new line\nanother" >> growing.txt

观察者打印

新队
其他

请参阅这篇文章以获取更多信息和一些一般性评论，并研究模块的文档和man inotify您的系统。

要做到这一点以及其他事情，你可以把它放在一个分叉的过程中，并在它们到来时将更改发送给父级（通过pipe、socketpair或文件）。在处理过程中发生的任何事件仍会被检测到，并在控件返回后作为新事件传递。

父母可以通过在循环中使用非阻塞或使用用户信号（）的信号处理程序来处理何时读取的问题，该用户信号（ ）在写入其管道末端后发送。IO::Select::can_readSIGUSR1

这是一个不太简单的东西的轮廓。也有现成的解决方案。AnyEvent生态系统中的一些选项是AnyEvent::Fork和朋友，AnyEvent::Subprocess及其“委托”机制，AnyEvent::Handle用于监视该管道何时可以读取。

所有这些都需要一个事件循环，在这种情况下，所有工作都在处理程序（回调）中完成。然后主要工作可以在“空闲观察者”中完成，但这可能会有点令人费解，在这种特殊情况下，概述的用于子管理的手动方法最终可能会更加清晰。

监视器的最合适管理取决于您的程序的详细信息。

如果文件以更改 inode 的方式更改，则上面的代码将无法检测到。这可能发生在许多常用工具上，例如zip,rsync等。为了防止这种情况以及可能的文件消失，您可以使用其他标志来检测这些事件。

$inotify->watch( $file, 
    IN_MODIFY |IN_ATTRIB | IN_MOVE_SELF | IN_DELETE_SELF,  
    sub {
        my $e = shift;
        my $name = $e->fullname;
        if ($e->IN_MODIFY) {
            print while <$fh>;
        }
        if ($e->IN_ATTRIB)      { say "$name meatadata changed" }
        if ($e->IN_MOVE_SELF)   { say "$name was moved" }
        if ($e->IN_DELETE_SELF) { say "$name was deleted" }
});

对于 inode 更改，它是IN_ATTRIB被触发的。

然后您可能需要重新打开该文件（并且可能首先找到它）。一个单独的目录监视器在这里会很有帮助。所有这些也可以通过单独使用目录监视器来完成。

于 2018-09-10T00:15:20.337 回答