22

我有一个存储一些键值对的函数，当我迭代它们时，我得到了两次这个错误：[dcc32 Error] App.pas(137): E2149 Class does not have a default property。这是我的代码的一部分：

function BuildString: string;
var
  i: Integer;
  requestContent: TDictionary<string, string>;
  request: TStringBuilder;
begin
  requestContent := TDictionary<string, string>.Create();

  try
    // add some key-value pairs
    request :=  TStringBuilder.Create;
    try
      for i := 0 to requestContent.Count - 1 do
      begin
        // here I get the errors
        request.Append(requestContent.Keys[i] + '=' +
          TIdURI.URLEncode(requestContent.Values[i]) + '&');
      end;

      Result := request.ToString;
      Result := Result.Substring(0, Result.Length - 1); //remove the last '&'
    finally
      request.Free;
    end; 
  finally
    requestContent.Free;
  end;
end;

我需要从字典中的每个项目中收集信息。我该如何解决？

4

1 回答 1

46

字典类的Keys和属性分别是 type和。这些类派生自索引并且不能通过索引进行迭代。但是，您可以迭代，或者实际上，做后者对您没有多大用处。ValuesTDictionary<string, string>.TKeyCollectionTDictionary<string, string>.TValueCollectionTEnumerable<T>KeysValues

如果您迭代Keys您的代码可能如下所示：

var
  Key: string;
....
for Key in requestContent.Keys do
  request.Append(Key + '=' + TIdURI.URLEncode(requestContent[Key]) + '&');

然而，这是低效的。由于您知道需要键和匹配值，因此可以使用字典的迭代器：

var 
  Item: TPair<string, string>; 
....
for Item in requestContent do 
  request.Append(Item.Key + '=' + TIdURI.URLEncode(Item.Value) + '&');

对迭代器比上面的第一个变体更有效。这是因为实现细节意味着对迭代器能够迭代字典而无需：

  1. 计算每个键的哈希码，以及
  2. 当哈希码发生冲突时执行线性探测。
于 2014-09-29T12:32:41.667 回答